You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 

81 lines
2.1 KiB

  1. # Copyright 1999-2020 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  3. EAPI="7"
  4. VALA_USE_DEPEND="vapigen"
  5. VALA_MIN_API_VERSION="0.32"
  6. inherit gnome.org meson vala xdg
  7. DESCRIPTION="Library providing a virtual terminal emulator widget"
  8. HOMEPAGE="https://wiki.gnome.org/Apps/Terminal/VTE"
  9. LICENSE="LGPL-3+ GPL-3+"
  10. SLOT="2.91"
  11. IUSE="+crypt debug gtk-doc +introspection mouse +vala vanilla"
  12. KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
  13. REQUIRED_USE="vala? ( introspection )"
  14. SRC_URI="${SRC_URI} !vanilla? ( https://dev.gentoo.org/~leio/distfiles/${PN}-0.58.3-command-notify.patch.xz )"
  15. RDEPEND="
  16. >=x11-libs/gtk+-3.16:3[introspection?]
  17. >=dev-libs/fribidi-1.0.0
  18. >=dev-libs/glib-2.40:2
  19. crypt? ( >=net-libs/gnutls-3.2.7:0= )
  20. >=x11-libs/pango-1.22.0
  21. >=dev-libs/libpcre2-10.21
  22. sys-libs/zlib
  23. introspection? ( >=dev-libs/gobject-introspection-1.56:= )
  24. x11-libs/pango[introspection?]
  25. "
  26. DEPEND="${RDEPEND}"
  27. BDEPEND="
  28. dev-libs/libxml2:2
  29. dev-util/glib-utils
  30. gtk-doc? ( >=dev-util/gtk-doc-1.13
  31. app-text/docbook-xml-dtd:4.1.2 )
  32. >=sys-devel/gettext-0.19.8
  33. virtual/pkgconfig
  34. vala? ( $(vala_depend) )
  35. "
  36. src_prepare() {
  37. if ! use vanilla; then
  38. # Part of https://src.fedoraproject.org/rpms/vte291/raw/f31/f/vte291-cntnr-precmd-preexec-scroll.patch
  39. # Adds OSC 777 support for desktop notifications in gnome-terminal or elsewhere
  40. eapply "${WORKDIR}"/${PN}-0.58.3-command-notify.patch
  41. fi
  42. # -Ddebugg option enables various debug support via VTE_DEBUG, but also ggdb3; strip the latter
  43. sed -e '/ggdb3/d' -i meson.build || die
  44. if ! use mouse; then
  45. eapply "${FILESDIR}"/${P}-disable-mouse.patch
  46. fi
  47. use vala && vala_src_prepare
  48. xdg_src_prepare
  49. }
  50. src_configure() {
  51. local emesonargs=(
  52. $(meson_use debug debugg)
  53. $(meson_use gtk-doc docs)
  54. $(meson_use introspection gir)
  55. -Dfribidi=true # pulled in by pango anyhow
  56. $(meson_use crypt gnutls)
  57. -Dgtk3=true
  58. -Dgtk4=false
  59. -Diconv=true
  60. $(meson_use vala vapi)
  61. )
  62. meson_src_configure
  63. }
  64. src_install() {
  65. meson_src_install
  66. mv "${ED}"/etc/profile.d/vte{,-${SLOT}}.sh || die
  67. }