diff --git a/dev-python/django-debug-toolbar/Manifest b/dev-python/django-debug-toolbar/Manifest
new file mode 100644
index 0000000..0e047a8
--- /dev/null
+++ b/dev-python/django-debug-toolbar/Manifest
@@ -0,0 +1 @@
+DIST django-debug-toolbar-3.1.1.tar.gz 228123 BLAKE2B 3d61bb862cac2015abe84c4d4ee1101879b78a36b65c1bb0f5f29d78eb6081eadd850cec3264a59b78ff83cbc6c93645610c7c23d303f61cace395f7a2303e0f SHA512 6b1fe161bc3e5488cf95b23a8e33236fff24db1ebd04b29376085916cb0ab8edf5d239cbf602a5caa45dd5532976e4414be93d4f5a5987f17f0459d6ae11fb9b
diff --git a/dev-python/django-debug-toolbar/django-debug-toolbar-3.1.1.ebuild b/dev-python/django-debug-toolbar/django-debug-toolbar-3.1.1.ebuild
new file mode 100644
index 0000000..af1cb9d
--- /dev/null
+++ b/dev-python/django-debug-toolbar/django-debug-toolbar-3.1.1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="A configurable set of panels that display debug information"
+HOMEPAGE="
+	https://pypi.org/project/django-debug-toolbar/
+	https://github.com/jazzband/django-debug-toolbar/"
+SRC_URI="https://github.com/jazzband/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/django-1.11[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+	)
+"
+
+distutils_enable_sphinx docs
+
+python_prepare_all() {
+	# This prevents distutils from installing 'tests' package, rm magic no more needed
+	sed -e "/find_packages/s:'tests':'tests.\*', 'tests':" -i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	emake test
+}
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc -r example/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/django-debug-toolbar/metadata.xml b/dev-python/django-debug-toolbar/metadata.xml
new file mode 100644
index 0000000..77f1654
--- /dev/null
+++ b/dev-python/django-debug-toolbar/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">jazzband/django-debug-toolbar</remote-id>
+		<remote-id type="pypi">django-debug-toolbar</remote-id>
+	</upstream>
+</pkgmetadata>