diff --git a/media-libs/mediastreamer2/Manifest b/media-libs/mediastreamer2/Manifest
new file mode 100644
index 0000000..3c1b10e
--- /dev/null
+++ b/media-libs/mediastreamer2/Manifest
@@ -0,0 +1 @@
+DIST mediastreamer2-5.1.3.tar.gz 25309943 BLAKE2B 4499d04ba9aa9159b7084bb99757319645126596568fabb8eca6e60742188e22d9585e437bec8c39f2597264ec89e5b8ac94a6e10398b1ff00304408e6d0990e SHA512 29d6b25e4957addc9809fb7f41a9a6b4a68e42a72ad2571242fd31f59af49fbae89fae87af541a64cd433495872cc8a0298a4d3398fe1d65d576f8cfe8c16097
diff --git a/media-libs/mediastreamer2/mediastreamer2-5.1.3.ebuild b/media-libs/mediastreamer2/mediastreamer2-5.1.3.ebuild
new file mode 100644
index 0000000..c976ba9
--- /dev/null
+++ b/media-libs/mediastreamer2/mediastreamer2-5.1.3.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Mediastreaming library for telephony application"
+HOMEPAGE="https://gitlab.linphone.org/BC/public/mediastreamer2"
+SRC_URI="https://gitlab.linphone.org/BC/public/${PN}/-/archive/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="alsa bv16 debug doc ffmpeg g726 g729 gsm jpeg matroska opengl opus pcap portaudio +pulseaudio qrcode speex srtp static-libs resample test theora tools +v4l vpx zrtp"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="zrtp? ( srtp )
+	resample? ( speex )
+	|| ( alsa portaudio pulseaudio )
+	|| ( ffmpeg opengl v4l )"
+
+RDEPEND="net-libs/bctoolbox[test?]
+	>=net-libs/ortp-5.1.3
+	alsa? ( media-libs/alsa-lib )
+	bv16? ( media-libs/bv16-floatingpoint )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	g726? ( media-libs/spandsp )
+	g729? ( media-libs/bcg729 )
+	gsm? ( media-sound/gsm )
+	jpeg? ( media-libs/libjpeg-turbo )
+	matroska? ( media-libs/bcmatroska2 )
+	opengl? ( media-libs/glew:0
+		x11-libs/libX11
+		virtual/opengl )
+	opus? ( media-libs/opus )
+	pcap? ( net-libs/libpcap )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+	qrcode? ( media-libs/zxing-cpp )
+	speex? ( media-libs/speex
+		media-libs/speexdsp )
+	srtp? ( net-libs/libsrtp:2 )
+	theora? ( media-libs/libtheora )
+	v4l? ( media-libs/libv4l )
+	vpx? ( media-libs/libvpx:= )
+	zrtp? ( net-libs/bzrtp[sqlite] )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_ALSA="$(usex alsa)"
+		-DENABLE_BV16="$(usex bv16)"
+		-DENABLE_DEBUG_LOGS="$(usex debug)"
+		-DENABLE_DOC="$(usex doc)"
+		-DENABLE_FFMPEG="$(usex ffmpeg)"
+		-DENABLE_G726="$(usex g726)"
+		-DENABLE_G729="$(usex g729)"
+		-DENABLE_G729B_CNG="$(usex g729)"
+		-DENABLE_GL="$(usex opengl)"
+		-DENABLE_GLX="$(usex opengl)"
+		-DENABLE_GSM="$(usex gsm)"
+		-DENABLE_JPEG="$(usex jpeg)"
+		-DENABLE_MKV="$(usex matroska)"
+		-DENABLE_OPUS="$(usex opus)"
+		-DENABLE_PCAP="$(usex pcap)"
+		-DENABLE_PORTAUDIO="$(usex portaudio)"
+		-DENABLE_PULSEAUDIO="$(usex pulseaudio)"
+		-DENABLE_QRCODE="$(usex qrcode)"
+		-DENABLE_RESAMPLE="$(usex resample)"
+		-DENABLE_SPEEX_CODEC="$(usex speex)"
+		-DENABLE_SPEEX_DSP="$(usex speex)"
+		-DENABLE_SRTP="$(usex srtp)"
+		-DENABLE_STATIC="$(usex static-libs)"
+		-DENABLE_THEORA="$(usex theora)"
+		-DENABLE_TOOLS="$(usex tools)"
+		-DENABLE_UNIT_TESTS="$(usex test)"
+		-DENABLE_V4L="$(usex v4l)"
+		-DENABLE_VPX="$(usex vpx)"
+		-DENABLE_ZRTP="$(usex zrtp)"
+	)
+
+	cmake_src_configure
+}
diff --git a/media-libs/mediastreamer2/metadata.xml b/media-libs/mediastreamer2/metadata.xml
new file mode 100644
index 0000000..3902854
--- /dev/null
+++ b/media-libs/mediastreamer2/metadata.xml
@@ -0,0 +1,34 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>spiderx@spiderx.dp.ua</email>
+		<name>Vladimir Pavljuchenkov</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<longdescription lang="en">
+	Powerful and lightweight streaming engine for voice/video telephony
+	applications. This media processing and streaming toolkit is
+	responsible for receiving and sending all multimedia streams in
+	Linphone, including voice/video capture, encoding and decoding,
+	and rendering.
+	</longdescription>
+	<use>
+		<flag name="bv16">Support for BroadVoice 16 kbs codec via <pkg>media-libs/bv16-floatingpoint</pkg></flag>
+		<flag name="g726">Support for SpanDSP codec via <pkg>media-libs/spandsp</pkg></flag>
+		<flag name="g729">Support for ITU G729 Annex A/B speech codec via <pkg>media-libs/bcg729</pkg></flag>
+		<flag name="pcap">Support for network packet capture via <pkg>net-libs/libpcap</pkg></flag>
+		<flag name="qrcode">Support for QR code via <pkg>media-libs/zxing-cpp</pkg></flag>
+		<flag name="srtp">Support for Secure Real-time Transport Protocol (SRTP) via <pkg>net-libs/libsrtp</pkg></flag>
+		<flag name="resample">Enable resampling capability</flag>
+		<flag name="tools">Build tools</flag>
+		<flag name="vpx">Support for VPX codec via <pkg>media-libs/libvpx</pkg></flag>
+		<flag name="zrtp">Support for Media Path Key Agreement for Unicast Secure RTP via <pkg>net-libs/bzrtp</pkg></flag>
+	</use>
+	<upstream>
+		<remote-id type="github">BelledonneCommunications/mediastreamer2</remote-id>
+	</upstream>
+</pkgmetadata>