From e07fadc0493265eb210ef6d3ae52c08312822e41 Mon Sep 17 00:00:00 2001
From: Alarig Le Lay <alarig@swordarmor.fr>
Date: Wed, 21 Jul 2021 18:49:24 +0200
Subject: [PATCH] x11-libs/vte: Version bump to 0.64.2

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Alarig Le Lay <alarig@swordarmor.fr
---
 x11-libs/vte/Manifest          |  1 +
 x11-libs/vte/vte-0.64.2.ebuild | 93 ++++++++++++++++++++++++++++++++++
 2 files changed, 94 insertions(+)
 create mode 100644 x11-libs/vte/vte-0.64.2.ebuild

diff --git a/x11-libs/vte/Manifest b/x11-libs/vte/Manifest
index 15fc69b..f95a7ca 100644
--- a/x11-libs/vte/Manifest
+++ b/x11-libs/vte/Manifest
@@ -1,2 +1,3 @@
 DIST vte-0.64.1-command-notify.patch.xz 4880 BLAKE2B d6ff5f4acac161980c8c18245e65795c7f0ea3d0819748894b055306ecd731d698cac578eff2750795a9180a9b17d79f220e814083012d5a04f4f351ff2a0e36 SHA512 174397aeca00399b138286fd4cc88941add041a1f2596fd42222d44c886c2e35b2a33041b58a102ee3acbcddc0cc40fcfde39d72ec46b640ee1db22d8ae684c4
 DIST vte-0.64.1.tar.bz2 486720 BLAKE2B bd8fb1f471a43aadf015cce8ae38c646521ca66e37652b72f7e94cec15a2a0a844d67116e9123ede44ba1b6ee569d1ecd0ff5e83067f6231802f5a77a798e446 SHA512 38bbbb4ed3d86740091c9ddee83f97bf5cb5c69c48e8a78592dd46e8f9334859a6c523e7b16dce110de71cd4a9a3b8b99a11816b61eae6e251dfc20cdbee6716
+DIST vte-0.64.2.tar.bz2 486837 BLAKE2B 3e127d61e4018607ca2df170108aef65b224a48df4d57545c98cbdb9753cbe7b9821e91a5bccd09d8c39af95d747a2ff01c69320e9245f5a82e7887b62c32c97 SHA512 6cbc1ee25a0ef2b00bcf26c07042eccc14fdea323e4445123db9fad05bf2e799579d723f6147c08712aec9b94e17003ce8f9e6ebe65278fdb3832cf77cba5be5
diff --git a/x11-libs/vte/vte-0.64.2.ebuild b/x11-libs/vte/vte-0.64.2.ebuild
new file mode 100644
index 0000000..92706fc
--- /dev/null
+++ b/x11-libs/vte/vte-0.64.2.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+VALA_USE_DEPEND="vapigen"
+VALA_MIN_API_VERSION="0.32"
+
+inherit gnome.org meson python-any-r1 vala xdg
+
+DESCRIPTION="Library providing a virtual terminal emulator widget"
+HOMEPAGE="https://wiki.gnome.org/Apps/Terminal/VTE"
+
+LICENSE="LGPL-3+ GPL-3+"
+SLOT="2.91"
+IUSE="+crypt debug gtk-doc +icu +introspection systemd mouse +vala vanilla"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
+REQUIRED_USE="vala? ( introspection )"
+
+# Upstream is hostile and refuses to upload tarballs.
+SRC_URI="https://gitlab.gnome.org/GNOME/${PN}/-/archive/${PV}/${P}.tar.bz2"
+SRC_URI="${SRC_URI} !vanilla? ( https://dev.gentoo.org/~mattst88/distfiles/${PN}-0.64.1-command-notify.patch.xz )"
+
+RDEPEND="
+	>=x11-libs/gtk+-3.24.14:3[introspection?]
+	>=dev-libs/fribidi-1.0.0
+	>=dev-libs/glib-2.52:2
+	crypt?  ( >=net-libs/gnutls-3.2.7:0= )
+	icu? ( dev-libs/icu:= )
+	>=x11-libs/pango-1.22.0
+	>=dev-libs/libpcre2-10.21
+	systemd? ( >=sys-apps/systemd-220:= )
+	sys-libs/zlib
+	introspection? ( >=dev-libs/gobject-introspection-1.56:= )
+	x11-libs/pango[introspection?]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.13
+		app-text/docbook-xml-dtd:4.1.2 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+
+	vala? ( $(vala_depend) )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.64.1-meson-Find-python-explicitly-to-honor-downstream-pyt.patch
+)
+
+src_prepare() {
+	if ! use vanilla; then
+		# Part of https://src.fedoraproject.org/rpms/vte291/raw/f31/f/vte291-cntnr-precmd-preexec-scroll.patch
+		# Adds OSC 777 support for desktop notifications in gnome-terminal or elsewhere
+		eapply "${WORKDIR}"/${PN}-0.64.1-command-notify.patch
+	fi
+
+	# -Ddebugg option enables various debug support via VTE_DEBUG, but also ggdb3; strip the latter
+	sed -e '/ggdb3/d' -i meson.build || die
+
+	if ! use mouse; then
+		eapply "${FILESDIR}"/${PN}-0.60.3-disable-mouse.patch
+	fi
+
+	use vala && vala_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Da11y=true
+		$(meson_use debug debugg)
+		$(meson_use gtk-doc docs)
+		$(meson_use introspection gir)
+		-Dfribidi=true # pulled in by pango anyhow
+		-Dglade=true
+		$(meson_use crypt gnutls)
+		-Dgtk3=true
+		-Dgtk4=false
+		$(meson_use icu)
+		$(meson_use systemd _systemd)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	mv "${ED}"/etc/profile.d/vte{,-${SLOT}}.sh || die
+}