net-mail/postorius: new package, add 1.3.8

net-mail/postorius/Manifest

@@ -0,0 +1 @@
+DIST postorius-1.3.8.tar.gz 3222195 BLAKE2B 83e48443feacf9b2adc2c231287c01e7753f12efce699fbb3e650ae929c2219129af7b090299bd7ee15584699a92725b6c7b778a29114abe88adc5f9330ea7d0 SHA512 49ea63687cf486f70d2e75935d3851df032727c4161334ff27042318f219670bce77726cb880512419cdedad67ffdaaea4517339e0c65854b0000086d3433aae

net-mail/postorius/metadata.xml

@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<!-- maintainer-needed -->
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">postorius</remote-id>
+		<remote-id type="gitlab">mailman/postorius</remote-id>
+	</upstream>
+</pkgmetadata>

net-mail/postorius/postorius-1.3.8.ebuild

@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="A web user interface for GNU Mailman 3"
+HOMEPAGE="https://www.list.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/django[${PYTHON_USEDEP}]
+	dev-python/readme_renderer[${PYTHON_USEDEP}]
+	net-mail/django-mailman3[${PYTHON_USEDEP}]
+	net-mail/mailmanclient[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/vcrpy[${PYTHON_USEDEP}]
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/pytest-django[${PYTHON_USEDEP}]
+		dev-python/isort[${PYTHON_USEDEP}]
+		net-mail/mailman[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( README.rst )
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -e 's/test_list_info/_&/' -i src/postorius/tests/mailman_api_tests/test_list_summary.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x PYTHONPATH="${S}/src"
+	cd example_project || die
+	epytest ../src
+}