From dc1ca785c78cd901f48d2653c2a75eeb1b944f25 Mon Sep 17 00:00:00 2001
From: Alarig Le Lay <alarig@swordarmor.fr>
Date: Tue, 31 Jan 2023 00:55:45 +0100
Subject: [PATCH] dev-python/odfpy: new package, add 1.4.2

---
 dev-python/odfpy/Manifest           |  1 +
 dev-python/odfpy/metadata.xml       | 13 ++++++++++
 dev-python/odfpy/odfpy-1.4.2.ebuild | 40 +++++++++++++++++++++++++++++
 3 files changed, 54 insertions(+)
 create mode 100644 dev-python/odfpy/Manifest
 create mode 100644 dev-python/odfpy/metadata.xml
 create mode 100644 dev-python/odfpy/odfpy-1.4.2.ebuild

diff --git a/dev-python/odfpy/Manifest b/dev-python/odfpy/Manifest
new file mode 100644
index 0000000..f2e97bf
--- /dev/null
+++ b/dev-python/odfpy/Manifest
@@ -0,0 +1 @@
+DIST odfpy-release-1.4.2.gh.tar.gz 10065808 BLAKE2B b339cb44604552ee530d8fa8385d753c1f9210f9335813ab279150b16d36f72263fc02c0d2c01ce4350dd3c81b94e7e9f394ce8ec2d85372eb972558a86ded0b SHA512 75368010c015e13302d2b43228ef9ed1f6c9307da60cf199098609729b008c69836511c953dbc730f3097124878b1fa6de7e8d5f49e20716062ada747698f84d
diff --git a/dev-python/odfpy/metadata.xml b/dev-python/odfpy/metadata.xml
new file mode 100644
index 0000000..76eb1be
--- /dev/null
+++ b/dev-python/odfpy/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">odfpy</remote-id>
+		<remote-id type="github">eea/odfpy</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/odfpy/odfpy-1.4.2.ebuild b/dev-python/odfpy/odfpy-1.4.2.ebuild
new file mode 100644
index 0000000..7e050a9
--- /dev/null
+++ b/dev-python/odfpy/odfpy-1.4.2.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+MY_P=${PN}-release-${PV}
+DESCRIPTION="Python API and tools to manipulate OpenDocument files"
+HOMEPAGE="
+	https://github.com/eea/odfpy/
+	https://pypi.org/project/odfpy/
+"
+SRC_URI="
+	https://github.com/eea/odfpy/archive/release-${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0 GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="examples"
+
+RDEPEND="
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc -r examples/.
+	fi
+	distutils-r1_python_install_all
+}