dev-python/graphene: Import from ::guru

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Alarig Le Lay <alarig@swordarmor.fr>

dev-python/graphene/Manifest

@@ -0,0 +1,2 @@
+DIST graphene-3.0.0_beta7.tar.gz 113258 BLAKE2B 4a3adadfea6dc6fd936b8bad83cf02c1b2b7937648712ee26ce3c5eb7e6d6631790ae2f22fff334de4495ed3197761862e88450e7f837ee06f71e7de4009efe4 SHA512 df4dee75c8c5bc5643dd5231bff61f7f1e2efe7203e61a3e32b10c80c2f44139a408ca99726fea51d6aa6e844e648c860c41e3e20ee4679dd3573f43047e71fa
+DIST sphinx-graphene-3.0.0_beta7.zip 22270 BLAKE2B 7cc467f12e7857cedb0336c7d0708f9429b9ccaa7f65077e6453a3e4ce0af92cbdb6d4dd3bec5801bd3e5fb233b4994dbce52fabe690da196ee25b5eec7fb63f SHA512 00cdaee50a7c16729d9d820de7d6c0f61215e3b906777b0705f2de0d2029f2ffb1f86134b1d673d00675d77729be47765999537fc42aeefafb026248b9b0b3b0

dev-python/graphene/graphene-3.0.0_beta7.ebuild

@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1
+
+MY_PV="${PV/_beta/b}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="GraphQL Framework for Python"
+HOMEPAGE="https://graphene-python.org
+	https://pypi.org/project/graphene
+	https://github.com/graphql-python/graphene
+"
+SRC_URI="https://github.com/graphql-python/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz
+	doc? ( https://graphene-python.org/sphinx_graphene_theme.zip -> sphinx-${P}.zip )
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/aniso8601[${PYTHON_USEDEP}]
+	dev-python/graphql-core[${PYTHON_USEDEP}]
+	dev-python/graphql-relay[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	doc? ( app-arch/unzip )
+	test? (
+		dev-python/iso8601[${PYTHON_USEDEP}]
+		dev-python/promise[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-benchmark[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/snapshottest[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_P}"
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs
+
+src_unpack() {
+	unpack ${P}.tar.gz
+
+	if use doc ; then
+		unpack sphinx-${P}.zip
+		mv "${WORKDIR}"/sphinx_graphene_theme "${S}"/docs || die
+	fi
+}
+
+python_test() {
+	epytest --benchmark-disable \
+		--deselect graphene/types/tests/test_schema.py::TestUnforgivingExecutionContext::test_unexpected_error
+}

dev-python/graphene/metadata.xml

@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+    <maintainer type="person">
+        <email>piotr.staroszczyk@get24.org</email>
+        <name>Piotr Staroszczyk</name>
+    </maintainer>
+</pkgmetadata>