diff --git a/dev-python/social-auth-core/Manifest b/dev-python/social-auth-core/Manifest
new file mode 100644
index 0000000..2b0bc89
--- /dev/null
+++ b/dev-python/social-auth-core/Manifest
@@ -0,0 +1 @@
+DIST social-core-4.2.0.tar.gz 193508 BLAKE2B 17aad9b12b49176bdd958995240121f66c664da97c2b8a53405fc067ee27174fc9c7ba504ef6026981c7d4286a8796f3ff05a2e2ebae8d038aa81d20e3c8234c SHA512 17fc36dfca6aabce9dbf622f6b2e6ce4eb1577d4df7b4a2b85a67b1131a5a2970b5a0ac4462bf5600ef62419da5e262955b2a2e00ec9bd222a7c2700f6199f64
diff --git a/dev-python/social-auth-core/metadata.xml b/dev-python/social-auth-core/metadata.xml
new file mode 100644
index 0000000..89b4f23
--- /dev/null
+++ b/dev-python/social-auth-core/metadata.xml
@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>spiderx@spiderx.dp.ua</email>
+		<name>Vladimir Pavljuchenkov</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<longdescription lang="en">
+	Python Social Auth is an easy to setup social authentication and
+	registration mechanism with support for several frameworks and
+	auth providers.
+	</longdescription>
+	<upstream>
+		<remote-id type="github">python-social-auth/social-core</remote-id>
+		<remote-id type="pypi">social-auth-core</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/social-auth-core/social-auth-core-4.2.0.ebuild b/dev-python/social-auth-core/social-auth-core-4.2.0.ebuild
new file mode 100644
index 0000000..be2bf63
--- /dev/null
+++ b/dev-python/social-auth-core/social-auth-core-4.2.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 optfeature
+
+MY_PN="${PN//-auth/}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python Social Auth - Core"
+HOMEPAGE="https://github.com/python-social-auth/social-core"
+SRC_URI="https://github.com/python-social-auth/${MY_PN}/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+S="${WORKDIR}/${MY_P}"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	dev-python/oauthlib[${PYTHON_USEDEP}]
+	dev-python/pyjwt[${PYTHON_USEDEP}]
+	dev-python/python3-openid[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/requests-oauthlib[${PYTHON_USEDEP}]"
+BDEPEND="test? ( dev-python/httpretty[${PYTHON_USEDEP}]
+		dev-python/python-jose[${PYTHON_USEDEP}]
+		dev-python/python3-saml[${PYTHON_USEDEP}] )"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# need network / credentials
+	social_core/tests/backends/test_livejournal.py::LiveJournalOpenIdTest::test_login
+	social_core/tests/backends/test_livejournal.py::LiveJournalOpenIdTest::test_partial_pipeline
+	social_core/tests/backends/test_ngpvan.py::NGPVANActionIDOpenIDTest::test_association_uid
+	social_core/tests/backends/test_ngpvan.py::NGPVANActionIDOpenIDTest::test_extra_data_phone
+	social_core/tests/backends/test_ngpvan.py::NGPVANActionIDOpenIDTest::test_login
+	social_core/tests/backends/test_ngpvan.py::NGPVANActionIDOpenIDTest::test_partial_pipeline
+	social_core/tests/backends/test_ngpvan.py::NGPVANActionIDOpenIDTest::test_user_data
+	social_core/tests/backends/test_steam.py::SteamOpenIdTest::test_login
+	social_core/tests/backends/test_steam.py::SteamOpenIdTest::test_partial_pipeline
+	social_core/tests/backends/test_ngpvan.py::NGPVANActionIDOpenIDTest::test_setup_request
+	social_core/tests/backends/test_steam.py::SteamOpenIdMissingSteamIdTest::test_login
+	social_core/tests/backends/test_steam.py::SteamOpenIdMissingSteamIdTest::test_partial_pipeline
+)
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${ED}" -type d -name "tests" -exec rm -rv {} + || die "tests removing failed"
+}
+
+pkg_postinst() {
+	optfeature "integration with OpenID Connect" dev-python/python-jose
+	optfeature "integration with SAML" dev-python/python3-saml dev-python/lxml
+}