From a7a37d3042cec5cbf4b3aa127ccb6db2ca521bca Mon Sep 17 00:00:00 2001
From: Alarig Le Lay <alarig@swordarmor.fr>
Date: Thu, 30 Mar 2023 12:13:52 +0200
Subject: [PATCH] dev-python/sphinxcontrib-blockdiag: new package, add 3.0.0

---
 dev-python/sphinxcontrib-blockdiag/Manifest   |  1 +
 .../sphinxcontrib-blockdiag/metadata.xml      | 16 ++++++
 .../sphinxcontrib-blockdiag-3.0.0.ebuild      | 53 +++++++++++++++++++
 3 files changed, 70 insertions(+)
 create mode 100644 dev-python/sphinxcontrib-blockdiag/Manifest
 create mode 100644 dev-python/sphinxcontrib-blockdiag/metadata.xml
 create mode 100644 dev-python/sphinxcontrib-blockdiag/sphinxcontrib-blockdiag-3.0.0.ebuild

diff --git a/dev-python/sphinxcontrib-blockdiag/Manifest b/dev-python/sphinxcontrib-blockdiag/Manifest
new file mode 100644
index 0000000..c01c25d
--- /dev/null
+++ b/dev-python/sphinxcontrib-blockdiag/Manifest
@@ -0,0 +1 @@
+DIST sphinxcontrib-blockdiag-3.0.0.gh.tar.gz 12300 BLAKE2B 4bb6e83625095aab209b3f8eff3f96dd0c0ff37c542bedd03d7b56be282bdb6929bba7ef9cbbc458492b17bfbcf80d705cb17b3f194213c1416bf1ab090fcc6a SHA512 1d03296007b0b6455fa25b1c0d3f09fb76dfaeba43ac7155033ec6fda0aaae40b757f6b77b63725489f2360eb5a80ce8e9e55eb6460b73c3b3bca363afe8aeac
diff --git a/dev-python/sphinxcontrib-blockdiag/metadata.xml b/dev-python/sphinxcontrib-blockdiag/metadata.xml
new file mode 100644
index 0000000..b212d7d
--- /dev/null
+++ b/dev-python/sphinxcontrib-blockdiag/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<maintainer>
+			<email>i.tkomiya@gmail.com</email>
+			<name>Takeshi KOMIYA</name>
+		</maintainer>
+		<remote-id type="github">blockdiag/sphinxcontrib-blockdiag</remote-id>
+		<remote-id type="pypi">sphinxcontrib-blockdiag</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/sphinxcontrib-blockdiag/sphinxcontrib-blockdiag-3.0.0.ebuild b/dev-python/sphinxcontrib-blockdiag/sphinxcontrib-blockdiag-3.0.0.ebuild
new file mode 100644
index 0000000..caa17bd
--- /dev/null
+++ b/dev-python/sphinxcontrib-blockdiag/sphinxcontrib-blockdiag-3.0.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A sphinx extension for embedding block diagrams using blockdiag"
+HOMEPAGE="
+	https://github.com/blockdiag/sphinxcontrib-blockdiag/
+	https://pypi.org/project/sphinxcontrib-blockdiag/
+"
+SRC_URI="
+	https://github.com/blockdiag/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~riscv ~s390 sparc x86"
+
+RDEPEND="
+	>=dev-python/sphinx-2.0[${PYTHON_USEDEP}]
+	>=dev-python/blockdiag-1.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/reportlab[${PYTHON_USEDEP}]
+		dev-python/sphinx-testing[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+python_prepare_all() {
+	sed -i -e "/build-base/d" setup.cfg || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	rm -rf sphinxcontrib || die
+	distutils_write_namespace sphinxcontrib
+	eunittest
+}