net-analyzer/netsniff-ng: New ebuild

This commit is contained in:
Alarig Le Lay 2020-02-26 23:59:38 +01:00
parent 3483f650b3
commit a6cc4f0b68
3 changed files with 98 additions and 0 deletions

View File

@ -0,0 +1 @@
DIST netsniff-ng-0.6.6.tar.xz 617204 BLAKE2B 9b8f018fa1ec53f211f9540fe1dff10e15ce615ab2c39b05917b5ddb0b87058f7aac6bff10a098371544a2e7706cc515fd0b25609db9cd10f6b8a689b70702e6 SHA512 f6d158e61c5be72506e2732e82e3863b24115abcb4642c5998b7225475c07d8566ff124f6e204e5a1919a57aef1d34ebf234076c16d99299847f8204777eb834

View File

@ -0,0 +1,12 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<maintainer type="person">
<email>alarig@swordarmor.fr</email>
<name>Alarig Le Lay</name>
</maintainer>
<maintainer type="project">
<email>proxy-maint@gentoo.org</email>
<name>Proxy Maintainers</name>
</maintainer>
</pkgmetadata>

View File

@ -0,0 +1,85 @@
# Copyright 1999-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit multilib toolchain-funcs
DESCRIPTION="high performance network sniffer for packet inspection"
HOMEPAGE="http://netsniff-ng.org/"
if [[ "${PV}" == *9999 ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/borkmann/${PN}.git"
else
SRC_URI="http://pub.${PN}.org/${PN}/${P}.tar.xz"
KEYWORDS="~amd64"
fi
LICENSE="GPL-2"
SLOT="0"
IUSE="debug geoip zlib"
RDEPEND="
dev-libs/libcli
dev-libs/libnl:3
dev-libs/userspace-rcu:=
net-libs/libnet:1.1
net-libs/libnetfilter_conntrack
net-libs/libpcap
sys-libs/ncurses:0=
geoip? ( dev-libs/geoip )
zlib? ( sys-libs/zlib:= )
"
DEPEND="${RDEPEND}"
BDEPEND="
sys-devel/flex
sys-devel/bison
dev-libs/libsodium
virtual/pkgconfig
"
src_prepare() {
default
sed -e '/CFLAGS/s:?=:+=:' \
-e '/CPPFLAGS/s:?=:+=:' \
-e '/CFLAGS/s:\(-g\|-O2\|-O3\|-m\(arch\|tune\)=native\)::g' \
-i Makefile || die
if ! grep -Fq nacl-20110221 curvetun/nacl_build.sh ; then
die "have nacl-20110221, expected $(grep ${MY_NACL_P} curvetun/nacl_build.sh)"
fi
export NACL_INC_DIR="${EROOT}/usr/include/nacl"
export NACL_LIB_DIR="${EROOT}/usr/$(get_libdir)/nacl"
# do not compress man pages by default
sed \
-e '/gzip/s@\$(Q).*$@$(Q)cp $(1).8 $(1)/$(1).8@' \
-e 's@\.8\.gz@.8@' \
-i Template || die
}
src_configure() {
local myconfargs=(
--prefix="${EPREFIX}/usr"
--sysconfdir="${EPREFIX}/etc"
$(usex debug --enable-debug '')
$(usex geoip '' --disable-geoip)
$(usex zlib '' --disable-zlib)
)
# not an autoconf generated configure
./configure "${myconfargs[@]}" || die
}
src_compile() {
emake CC="$(tc-getCC)" LD="$(tc-getCC)" CCACHE="" \
LEX=lex YAAC=bison STRIP=true \
Q= HARDENING=1
}
src_install() {
emake PREFIX="${ED}/usr" ETCDIR="${ED}/etc" install
dodoc AUTHORS README REPORTING-BUGS
}