From 91af35d82644f43fd189da8bdc9ae17a4c158921 Mon Sep 17 00:00:00 2001
From: Alarig Le Lay <alarig@swordarmor.fr>
Date: Tue, 21 Mar 2023 20:18:46 +0100
Subject: [PATCH] dev-python/lazr-config: new package, add 2.2.3-r2

---
 dev-python/lazr-config/Manifest               |  1 +
 .../lazr-config/lazr-config-2.2.3-r2.ebuild   | 45 +++++++++++++++++++
 dev-python/lazr-config/metadata.xml           | 15 +++++++
 3 files changed, 61 insertions(+)
 create mode 100644 dev-python/lazr-config/Manifest
 create mode 100644 dev-python/lazr-config/lazr-config-2.2.3-r2.ebuild
 create mode 100644 dev-python/lazr-config/metadata.xml

diff --git a/dev-python/lazr-config/Manifest b/dev-python/lazr-config/Manifest
new file mode 100644
index 0000000..a1848ab
--- /dev/null
+++ b/dev-python/lazr-config/Manifest
@@ -0,0 +1 @@
+DIST lazr-config-2.2.3.tar.gz 34213 BLAKE2B 029bdec3ac4f937f439f833f51e44a58f4604f337979c9f06695e7a243b2cde0af39a46139af5e88052e8585d2729c1b328df89979c9ff100338ec557e841b71 SHA512 cd8edc29a811b658045f314b2de4317bd750a701c2596d89912948fe0e58bdc39ad3d22cdf34bb7e46658af7ac6d32249e454c35bdcf72bc5053094343cd37bb
diff --git a/dev-python/lazr-config/lazr-config-2.2.3-r2.ebuild b/dev-python/lazr-config/lazr-config-2.2.3-r2.ebuild
new file mode 100644
index 0000000..81787b1
--- /dev/null
+++ b/dev-python/lazr-config/lazr-config-2.2.3-r2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+
+DESCRIPTION="Create configuration schemas, and process and validate configurations"
+HOMEPAGE="https://code.launchpad.net/lazr.config"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/lazr-delegates[${PYTHON_USEDEP}]
+	dev-python/zope-interface[${PYTHON_USEDEP}]
+	!dev-python/namespace-lazr
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# strip rdep specific to namespaces
+	sed -i -e "/'setuptools'/d" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	distutils_write_namespace lazr
+	epytest
+}
diff --git a/dev-python/lazr-config/metadata.xml b/dev-python/lazr-config/metadata.xml
new file mode 100644
index 0000000..7bef018
--- /dev/null
+++ b/dev-python/lazr-config/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<maintainer type="person">
+		<email>prometheanfire@gentoo.org</email>
+		<name>Matthew Thode</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">lazr.config</remote-id>
+	</upstream>
+</pkgmetadata>