dev-util/clippy: add 10.0

dev-util/clippy/Manifest

@@ -1 +1,2 @@
+DIST frr-10.0.tar.gz 10956257 BLAKE2B 608a0f06f9db5822f10f9dcf240df35ec9b65c1624f34d07f3dd5317868af03f2e897baf373d83cf86fa5944c2b7dcac6f6309f32d15b7c92b74c7f24be04e03 SHA512 f02fe672d3ab7382752f83a8ae1e6198e6b906b4ad31063aad18b803c8756b40fa1f280c5dafe872dea505bcc882fbb8392802411f9fac0ab0bd45dac8b3ed28
 DIST frr-9.1.tar.gz 10779477 BLAKE2B ba64f9455c38441f8cadce4eed435fb86344244e98bd1b675335887fb098be29adc035d722d3c128e136a4c6b0aa1adcbdc0e22815702e52170da940a5caf20a SHA512 77b278a3ea87da9dfd7b87e4f9ae67f08ed0f24809f6dd228d2ab2e2c29e2b3191d59d50fc474e53e159ac6c79c302481b462125d0657889516f07b8e05e8562

dev-util/clippy/clippy-10.0.ebuild

@@ -0,0 +1,58 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_P="frr-${PV}"
+PYTHON_COMPAT=( python3_{9..12} )
+inherit autotools python-single-r1
+
+DESCRIPTION="Standalone clippy tool built from FRR sources"
+HOMEPAGE="https://frrouting.org/"
+SRC_URI="https://github.com/FRRouting/frr/archive/${MY_P}.tar.gz"
+S="${WORKDIR}/frr-${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# standalone clippy does not have any tests
+# restrict to prevent bug 811753
+RESTRICT="test"
+
+DEPEND="
+	${PYTHON_DEPS}
+	virtual/libelf:=
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+"
+
+QA_CONFIG_IMPL_DECL_SKIP=(
+	mallinfo	# check in configure is fallback is needed
+	mallinfo2	# check in configure is fallback is needed
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# bug #884291
+	unset YACC
+	export LEX=flex
+
+	econf --enable-clippy-only
+}
+
+src_install() {
+	# 830087
+	find "lib" -type f -name "clippy" -print0 |
+		xargs -0 file | grep executable | grep ELF | cut -f 1 -d : |
+		xargs -I '{}' dobin '{}' ||
+		die "Failed to install 'lib/clippy'"
+}