dev-python/graphene: new package, add 3.0.0

dev-python/graphene/Manifest

@@ -0,0 +1,2 @@
+DIST graphene-3.0.0.tar.gz 116388 BLAKE2B 8e0c5732a8c267e1f492c4d07b070a40777e2ac7b41badc0c4b06471c4268e58bab47d170cf3e74940755f0de3d4be246c1a67eae44654bcfbf531fa1eeefb6d SHA512 dbd651ad509248e66c739acc16778753817b040e573514820a221647e1cf4fb96d22f499d1479eb39d921f17c696fcfe9acce3bb2b89b23ffd9e43f949dc4262
+DIST sphinx-graphene-3.0.0.zip 22270 BLAKE2B 7cc467f12e7857cedb0336c7d0708f9429b9ccaa7f65077e6453a3e4ce0af92cbdb6d4dd3bec5801bd3e5fb233b4994dbce52fabe690da196ee25b5eec7fb63f SHA512 00cdaee50a7c16729d9d820de7d6c0f61215e3b906777b0705f2de0d2029f2ffb1f86134b1d673d00675d77729be47765999537fc42aeefafb026248b9b0b3b0

dev-python/graphene/graphene-3.0.0.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+MY_PV="${PV/_beta/b}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="GraphQL Framework for Python"
+HOMEPAGE="https://graphene-python.org
+	https://pypi.org/project/graphene/
+	https://github.com/graphql-python/graphene
+"
+SRC_URI="https://github.com/graphql-python/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz
+	doc? ( https://graphene-python.org/sphinx_graphene_theme.zip -> sphinx-${P}.zip )
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/aniso8601[${PYTHON_USEDEP}]
+	dev-python/graphql-core[${PYTHON_USEDEP}]
+	dev-python/graphql-relay[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	doc? ( app-arch/unzip )
+	test? (
+		dev-python/iso8601[${PYTHON_USEDEP}]
+		dev-python/promise[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-benchmark[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/snapshottest[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_P}"
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs
+
+EPYTEST_DESELECT=(
+	graphene/types/tests/test_objecttype.py::test_objecttype_as_container_extra_args
+	graphene/types/tests/test_objecttype.py::test_objecttype_as_container_invalid_kwargs
+	graphene/types/tests/test_schema.py::TestUnforgivingExecutionContext::test_unexpected_error
+)
+
+src_unpack() {
+	unpack ${P}.tar.gz
+
+	if use doc; then
+		unpack sphinx-${P}.zip
+		mv "${WORKDIR}"/sphinx_graphene_theme "${S}"/docs || die
+	fi
+}
+
+python_test() {
+	epytest --benchmark-disable
+}

dev-python/graphene/metadata.xml

@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+    <maintainer type="person">
+        <email>piotr.staroszczyk@get24.org</email>
+        <name>Piotr Staroszczyk</name>
+    </maintainer>
+</pkgmetadata>