app-crypt/yubikey-manager: Allow >=dev-python/fido2-0.8

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Alarig Le Lay <alarig@swordarmor.fr

app-crypt/yubikey-manager/Manifest

@@ -0,0 +1 @@
+DIST yubikey-manager-3.1.1.tar.gz 116632 BLAKE2B 252c419280143fa6f44daf3de8ec27bbdc3218e4552e39799e1daca5b46939c4042ae1d43abeab110fe1abaf2e87d94c270442ee6fce05e26927add5b34e9f66 SHA512 8229d5442ddf89fe90abb0153aa005cb0d149a84634b994dc283f7cbac2f72d4b913c238c277c6aa07f431aed8905008aeb11e594e730be71c9ca88150a6ef68

app-crypt/yubikey-manager/metadata.xml

@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>gokturk@gentoo.org</email>
+    <name>Göktürk Yüksek</name>
+  </maintainer>
+  <longdescription>
+    Yubikey Manager is a python library and command line tool for
+    configuring any YubiKey over all USB transports. It's a CLI
+    successor of yubikey-neo-manager.
+  </longdescription>
+</pkgmetadata>

app-crypt/yubikey-manager/yubikey-manager-3.1.1-r1.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit readme.gentoo-r1 distutils-r1
+
+DESCRIPTION="Python library and command line tool for configuring a YubiKey"
+HOMEPAGE="https://developers.yubico.com/yubikey-manager/"
+# Per https://github.com/Yubico/yubikey-manager/issues/217, Yubico is
+# the official source for tarballs, not Github
+SRC_URI="https://developers.yubico.com/${PN}/Releases/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	>=dev-python/fido2-0.7.0[${PYTHON_USEDEP}]
+	dev-python/pyopenssl[${PYTHON_USEDEP}]
+	dev-python/pyscard[${PYTHON_USEDEP}]
+	dev-python/pyusb[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=sys-auth/ykpers-1.19.0
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+	)
+"
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	local DOC_CONTENTS
+
+	distutils-r1_python_install_all
+
+	DOC_CONTENTS="
+		The 'openpgp' command may require the package 'app-crypt/ccid'
+		to be installed on the system. Furthermore, make sure that pcscd
+		daemon is running and has correct access permissions to USB
+		devices.
+	"
+	readme.gentoo_create_doc
+
+	doman "${S}"/man/ykman.1
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}