From 7f65d591a1637466cfd2566233ef98445c22b01f Mon Sep 17 00:00:00 2001
From: Alarig Le Lay <alarig@swordarmor.fr>
Date: Tue, 25 Aug 2020 10:20:38 +0200
Subject: [PATCH] net-misc/FORT-validator: Version bump to 1.4.0

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Alarig Le Lay <alarig@swordarmor.fr
---
 .../FORT-validator-1.4.0.ebuild               | 77 +++++++++++++++++++
 net-misc/FORT-validator/Manifest              |  1 +
 2 files changed, 78 insertions(+)
 create mode 100644 net-misc/FORT-validator/FORT-validator-1.4.0.ebuild

diff --git a/net-misc/FORT-validator/FORT-validator-1.4.0.ebuild b/net-misc/FORT-validator/FORT-validator-1.4.0.ebuild
new file mode 100644
index 0000000..ce424e3
--- /dev/null
+++ b/net-misc/FORT-validator/FORT-validator-1.4.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools fcaps systemd
+
+DESCRIPTION="FORT validator is an open source RPKI validator"
+HOMEPAGE="https://fortproject.net/validator?2"
+SRC_URI="https://github.com/NICMx/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+MY_PN="fort"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="caps libressl"
+
+DEPEND="
+	acct-group/fort
+	acct-user/fort
+	caps? ( sys-libs/libcap )
+	dev-libs/jansson
+	libressl?	( dev-libs/libressl:0= )
+	!libressl?	( dev-libs/openssl:0= )
+"
+RDEPEND="
+	${DEPEND}
+	net-misc/rsync
+"
+BDEPEND="
+	sys-devel/autoconf
+	sys-devel/automake
+"
+
+PATCHES="${FILESDIR}/${PN}-skip-online-test.patch"
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_install() {
+	newinitd "${FILESDIR}/${MY_PN}-initd" ${MY_PN}
+	newconfd "${FILESDIR}/${MY_PN}-confd" ${MY_PN}
+
+	emake DESTDIR="${D}" install
+	insinto /usr/share/${MY_PN}/
+	insopts -m0644 -o "${MY_PN}"
+	diropts -m0755 -o "${MY_PN}"
+	doins -r examples/tal/
+
+	dodoc -r examples/
+
+	insinto /etc/fort
+	newins "${FILESDIR}/fort-config.json" config.json
+
+	exeinto "/usr/libexec/${MY_PN}"
+	doexe fort_setup.sh
+
+	systemd_dounit "${FILESDIR}/${MY_PN}.service"
+}
+
+pkg_postinst() {
+	fcaps cap_net_bind_service usr/bin/fort
+
+	einfo ""
+	einfo "ARIN TAL is disabled by default because the ARIN Relying Party"
+	einfo "Agreement must be accepted beforehead. Start fort, run"
+	einfo ""
+	einfo "  su -s /bin/sh -c '${EROOT}/usr/libexec/${MY_PN}/fort_setup.sh /usr/share/${MY_PN}/tal/' fort"
+	einfo ""
+	einfo "as root and restart fort to enable it."
+	einfo "The configuration file generation will provide a config file, but a"
+	einfo "simpler one is shiped with the ebuid. Use the one you prefer."
+}
diff --git a/net-misc/FORT-validator/Manifest b/net-misc/FORT-validator/Manifest
index 2ed1991..d5c4002 100644
--- a/net-misc/FORT-validator/Manifest
+++ b/net-misc/FORT-validator/Manifest
@@ -1,3 +1,4 @@
 DIST FORT-validator-1.2.0.tar.gz 427483 BLAKE2B 05fbec44fb17fa188b6196a2b166f2e112224dcf4071cc875ed1f3a147b28acff94c89b0c0a658aaee197e1820d9f53803e73add81e355f7df07713fcdb0df00 SHA512 e89b1aa7c0cd4036d04a017898e1a6017450f5dab96e57c35b0aa532b212b23f7fab17ca117a9461c9bdacca511ea70341e692a4d5e8f277ae8e277c1d48706e
 DIST FORT-validator-1.2.1.tar.gz 431832 BLAKE2B 25459e591a531dcf3326baec06c9e462611f1fd727bd79623d0f5eae0f02b2398e698ea6f0cf7608061f5e125afb056c7dff9b1dcc6fbe01332e573e8c4b1f15 SHA512 87d256a02ca6d3c00bb2245476c126b076f6c57e9eeaefb2dcb0dfed5763b5769731de08e4168c9ce701a2820eeda69c3bf054c8445b910948504fdb7b0b6b50
 DIST FORT-validator-1.3.0.tar.gz 444918 BLAKE2B 3a8fb8cce5c71d22ab402d6b6a1478f173641a3876bad04e9fde4373d2a6b49395ff692aa048579886a82a799ed7849fc51d86c798b0b0ea9c594b4eb532b367 SHA512 0aed86979e6b9c3142cc9a53d13a619dbe22a3e05bcc26f30fda5048ac3e9d31b83307fbd4a68543eaf948954dbaba54edbce9b90ab0189d15c3629b220d094c
+DIST FORT-validator-1.4.0.tar.gz 468621 BLAKE2B f531f06136e8052ca8a001c91c8209bba7f0da6dcbb8cbccf9d7b3d39e2366951f48f254614def4749a8eb3f83bf01afaf9e2b013eecbc8fcd0c4274c4c3496a SHA512 dfbd94c9fbd8a4eac9f43030ebfa005febc01e4a39fccdd58fbfcc79aadfe0eeb2f8a2f4836c8d14c3e957f58e91466650ff1a266144f4b4f731495f8a74e460