From 7be1483e92d428f9a0deb57e95b29d699516e7af Mon Sep 17 00:00:00 2001
From: Alarig Le Lay <alarig@swordarmor.fr>
Date: Wed, 22 Sep 2021 12:46:05 +0200
Subject: [PATCH] dev-python/ruamel-yaml: ::gentoo version is too high

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Alarig Le Lay <alarig@swordarmor.fr
---
 dev-python/ruamel-yaml/Manifest               |  1 +
 dev-python/ruamel-yaml/metadata.xml           | 29 +++++++++++
 .../ruamel-yaml/ruamel-yaml-0.16.13.ebuild    | 50 +++++++++++++++++++
 3 files changed, 80 insertions(+)
 create mode 100644 dev-python/ruamel-yaml/Manifest
 create mode 100644 dev-python/ruamel-yaml/metadata.xml
 create mode 100644 dev-python/ruamel-yaml/ruamel-yaml-0.16.13.ebuild

diff --git a/dev-python/ruamel-yaml/Manifest b/dev-python/ruamel-yaml/Manifest
new file mode 100644
index 0000000..948b3ad
--- /dev/null
+++ b/dev-python/ruamel-yaml/Manifest
@@ -0,0 +1 @@
+DIST ruamel-yaml-0.16.13.tar.xz 178756 BLAKE2B 19ee4713786a33853f42256e5cd3187e9e19b931ebd83a133365de3f080721c5a6f5fb41ff3079473461df47a0ab149981c5e94d08321da8b3c9eb311c226945 SHA512 1366fc0b3b5ea2699ca324636403576134ccc7c725b13c21a7752d1b16c644c93c7f7d82ddc337087d2c02947f95263d7a3fdd162f552ac3a78fa36f1f17b3f1
diff --git a/dev-python/ruamel-yaml/metadata.xml b/dev-python/ruamel-yaml/metadata.xml
new file mode 100644
index 0000000..5214b2a
--- /dev/null
+++ b/dev-python/ruamel-yaml/metadata.xml
@@ -0,0 +1,29 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>andrey_utkin@gentoo.org</email>
+		<name>Andrey Utkin</name>
+	</maintainer>
+	<maintainer type="person">
+		<email>marecki@gentoo.org</email>
+		<name>Marek Szuba</name>
+	</maintainer>
+	<maintainer type="person" proxied="yes">
+		<email>zoltan@sinustrom.info</email>
+		<name>Zoltan Puskas</name>
+	</maintainer>
+	<maintainer type="project" proxied="proxy">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">ruamel.yaml</remote-id>
+		<remote-id type="sourceforge">ruamel-yaml</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/ruamel-yaml/ruamel-yaml-0.16.13.ebuild b/dev-python/ruamel-yaml/ruamel-yaml-0.16.13.ebuild
new file mode 100644
index 0000000..9cf177b
--- /dev/null
+++ b/dev-python/ruamel-yaml/ruamel-yaml-0.16.13.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python3_{8..10} )
+
+inherit distutils-r1
+
+MY_PN="${PN//-/.}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="YAML parser/emitter that supports roundtrip comment preservation"
+HOMEPAGE="
+	https://pypi.org/project/ruamel.yaml/
+	https://sourceforge.net/p/ruamel-yaml/"
+# PyPI tarballs do not include tests
+SRC_URI="mirror://sourceforge/ruamel-dl-tagged-releases/${MY_P}.tar.xz -> ${P}.tar.xz"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	dev-python/namespace-ruamel[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml-clib[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/ruamel-std-pathlib[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+# Old PyYAML tests from lib/ require special set-up and are invoked indirectly
+# via test_z_olddata, tell pytest itself to leave the subdir alone.
+python_test() {
+	local deselect=()
+
+	[[ ${EPYTHON} == pypy3 ]] && deselect+=(
+		_test/test_deprecation.py::test_collections_deprecation
+	)
+
+	epytest --ignore _test/lib/ ${deselect[@]/#/--deselect }
+}
+
+python_install() {
+	distutils-r1_python_install --single-version-externally-managed
+	find "${ED}" -name '*.pth' -delete || die
+}