Browse Source

x11-libs/vte: Version bump to 0.58.3

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Alarig Le Lay <alarig@swordarmor.fr>
net-misc/routinator-0.7.0_rc1
Alarig Le Lay 5 months ago
parent
commit
63712bc2cd
Signed by: alarig <alarig@swordarmor.fr> GPG Key ID: 7AFE62C6DF8BCDEC
5 changed files with 82 additions and 96 deletions
  1. +2
    -2
      x11-libs/vte/Manifest
  2. +0
    -0
      x11-libs/vte/files/vte-0.58.3-disable-mouse.patch
  3. +0
    -1
      x11-libs/vte/metadata.xml
  4. +0
    -93
      x11-libs/vte/vte-0.56.4-r1.ebuild
  5. +80
    -0
      x11-libs/vte/vte-0.58.3-r1.ebuild

+ 2
- 2
x11-libs/vte/Manifest View File

@@ -1,2 +1,2 @@
DIST vte-0.54.1-command-notify.patch.xz 3428 BLAKE2B 75b0c22720276300be2e49e8444aa68fed77fb7a6cc6b0e93a5c2d41257626bd60ff1084d68579769cb3d85e7ec567927591746de48e860b138d0c1f24f64cc7 SHA512 a53da569f8168c8e9e21e186dcfc00bf9fdb78a0c767ba35033c1c1e4f836406b4d9bf70ee3e071f6c749fd6f72101a6960d201617bd0bc23021e1eeaac6fd0c
DIST vte-0.56.4.tar.xz 1100952 BLAKE2B 3c3ec69f4078bdb07a4501df4aeb31aaeb7f9fa5a4631152d486fbb2c950362612cd9dff4abe25b93da6c712a37a20ccbf050ad33d96ec7b997bb1409189f60b SHA512 5a6c79b30f07c1f5848ef59028864d893cc605b9ad8f49ae819958aaed962d2ff96baad379f126381b8bf00015003c5a6dc28c792e4e050ba35090338bd7dabb
DIST vte-0.58.3-command-notify.patch.xz 4964 BLAKE2B f8414d3bf124bd3de4c08e22a051feabdb11fbded7562a0bf9858fb8b8cf6327a3fdf7e18592eacd9f3608af5b720fe9a0cb598092a12c816d37d36899d88f6b SHA512 0de06ec0019127ec2729950228f8cae3e61a306207e177b8427789d4f6477f102d78232bd7f1a6e02cc218f507474427ad8366bc3c16c8a305b432dba96ba685
DIST vte-0.58.3.tar.xz 514844 BLAKE2B 1f48e95ec81397937c8a5a3d34ea9a7d1835d6cacec6e1b90b78568505d509b375f55678462428dd01da00e7290e4543bbab2dbb0aea46a322788fbaf022427b SHA512 b0a38eb1cd7d923b0431af943dbdb89932833f9a2b0b8fc1fa9ee728c87418c1f5a424b2ccee661721093a80c569f3b41c721b0ba2302ba0c3a42d4c5e31aa9a

x11-libs/vte/files/vte-0.56.4-disable-mouse.patch → x11-libs/vte/files/vte-0.58.3-disable-mouse.patch View File


+ 0
- 1
x11-libs/vte/metadata.xml View File

@@ -6,7 +6,6 @@
<name>Gentoo GNOME Desktop</name>
</maintainer>
<use>
<flag name="glade">Provide integration with <pkg>dev-util/glade</pkg>.</flag>
<flag name="mouse">Enable mouse support.</flag>
</use>
</pkgmetadata>

+ 0
- 93
x11-libs/vte/vte-0.56.4-r1.ebuild View File

@@ -1,93 +0,0 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI="6"
VALA_USE_DEPEND="vapigen"
VALA_MIN_API_VERSION="0.32"

inherit gnome2 vala

DESCRIPTION="Library providing a virtual terminal emulator widget"
HOMEPAGE="https://wiki.gnome.org/Apps/Terminal/VTE"

LICENSE="LGPL-2+"
SLOT="2.91"
IUSE="+crypt debug glade +introspection mouse vala vanilla"
KEYWORDS="~alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~sh sparc x86 ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
REQUIRED_USE="vala? ( introspection )"

SRC_URI="${SRC_URI} !vanilla? ( https://dev.gentoo.org/~leio/distfiles/${PN}-0.54.1-command-notify.patch.xz )"

RDEPEND="
>=dev-libs/glib-2.40:2
>=dev-libs/libpcre2-10.21
>=x11-libs/gtk+-3.16:3[introspection?]
>=x11-libs/pango-1.22.0

sys-libs/ncurses:0=
sys-libs/zlib

crypt? ( >=net-libs/gnutls-3.2.7:0= )
glade? ( >=dev-util/glade-3.9:3.10 )
introspection? ( >=dev-libs/gobject-introspection-0.9.0:= )
"
DEPEND="${RDEPEND}
dev-libs/libxml2:2
dev-util/glib-utils
>=dev-util/gtk-doc-am-1.13
>=dev-util/intltool-0.35
sys-devel/gettext
virtual/pkgconfig

vala? ( $(vala_depend) )
"
RDEPEND="${RDEPEND}
!x11-libs/vte:2.90[glade]
"

src_prepare() {
if ! use vanilla; then
# Part of https://src.fedoraproject.org/rpms/vte291/blob/f30/f/vte291-cntr-ntfy-scroll.patch
# Patch distfile for 0.54 series is re-used, as only git hashes and co changed in patchset.
# Adds OSC 777 support for desktop notifications in gnome-terminal or elsewhere
eapply "${WORKDIR}"/${PN}-0.54.1-command-notify.patch
fi

use vala && vala_src_prepare

# build fails because of -Werror with gcc-5.x
sed -e 's#-Werror=format=2#-Wformat=2#' -i configure || die "sed failed"

if ! use mouse; then
epatch "${FILESDIR}"/${P}-disable-mouse.patch
fi

gnome2_src_prepare
}

src_configure() {
local myconf=""

if [[ ${CHOST} == *-interix* ]]; then
myconf="${myconf} --disable-Bsymbolic"

# interix stropts.h is empty...
export ac_cv_header_stropts_h=no
fi

gnome2_src_configure \
--disable-static \
--with-gtk=3.0 \
--with-iconv \
$(use_enable debug) \
$(use_enable glade glade-catalogue) \
$(use_with crypt gnutls) \
$(use_enable introspection) \
$(use_enable vala) \
${myconf}
}

src_install() {
gnome2_src_install
mv "${ED}"/etc/profile.d/vte{,-${SLOT}}.sh || die
}

+ 80
- 0
x11-libs/vte/vte-0.58.3-r1.ebuild View File

@@ -0,0 +1,80 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI="7"
VALA_USE_DEPEND="vapigen"
VALA_MIN_API_VERSION="0.32"

inherit gnome.org meson vala xdg

DESCRIPTION="Library providing a virtual terminal emulator widget"
HOMEPAGE="https://wiki.gnome.org/Apps/Terminal/VTE"

LICENSE="LGPL-3+ GPL-3+"
SLOT="2.91"
IUSE="+crypt debug gtk-doc +introspection mouse +vala vanilla"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
REQUIRED_USE="vala? ( introspection )"

SRC_URI="${SRC_URI} !vanilla? ( https://dev.gentoo.org/~leio/distfiles/${PN}-0.58.3-command-notify.patch.xz )"

RDEPEND="
>=x11-libs/gtk+-3.16:3[introspection?]
>=dev-libs/fribidi-1.0.0
>=dev-libs/glib-2.40:2
crypt? ( >=net-libs/gnutls-3.2.7:0= )
>=x11-libs/pango-1.22.0
>=dev-libs/libpcre2-10.21
sys-libs/zlib
introspection? ( >=dev-libs/gobject-introspection-1.56:= )
x11-libs/pango[introspection?]
"
DEPEND="${RDEPEND}"
BDEPEND="
dev-libs/libxml2:2
dev-util/glib-utils
gtk-doc? ( >=dev-util/gtk-doc-1.13
app-text/docbook-xml-dtd:4.1.2 )
>=sys-devel/gettext-0.19.8
virtual/pkgconfig

vala? ( $(vala_depend) )
"

src_prepare() {
if ! use vanilla; then
# Part of https://src.fedoraproject.org/rpms/vte291/raw/f31/f/vte291-cntnr-precmd-preexec-scroll.patch
# Adds OSC 777 support for desktop notifications in gnome-terminal or elsewhere
eapply "${WORKDIR}"/${PN}-0.58.3-command-notify.patch
fi

# -Ddebugg option enables various debug support via VTE_DEBUG, but also ggdb3; strip the latter
sed -e '/ggdb3/d' -i meson.build || die

if ! use mouse; then
eapply "${FILESDIR}"/${P}-disable-mouse.patch
fi

use vala && vala_src_prepare
xdg_src_prepare
}

src_configure() {
local emesonargs=(
$(meson_use debug debugg)
$(meson_use gtk-doc docs)
$(meson_use introspection gir)
-Dfribidi=true # pulled in by pango anyhow
$(meson_use crypt gnutls)
-Dgtk3=true
-Dgtk4=false
-Diconv=true
$(meson_use vala vapi)
)
meson_src_configure
}

src_install() {
meson_src_install
mv "${ED}"/etc/profile.d/vte{,-${SLOT}}.sh || die
}

Loading…
Cancel
Save