Upgrading dev-python/commonmark, dev-python/recommonmark and dev-python/sphinxcontrib-websupport

dev-python/commonmark/Manifest

@@ -0,0 +1 @@
+DIST commonmark-0.8.1.tar.gz 90795 BLAKE2B 718c2b1af035672d74e2c6b6f89ea0cd23f45d7b0e47b6dadeef742d772f5458e08ec5f69fd4f34df9ab2c491d9d7add4c4acc7018c4048649aa0d8244d7db91 SHA512 dbab51d45c1973a8d0906148d785fb8ddc2b52177dfe0e69fe79bef2a5eb05a5a7ab8693852f4aaa8545af19d741569d04a24f06ea65171e6e80d9f66af47fdf

dev-python/commonmark/commonmark-0.8.1-r1.ebuild

@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_{6,7,8}} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python parser for the CommonMark Markdown spec"
+HOMEPAGE="https://github.com/rtfd/CommonMark-py"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/future[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	test? (
+		>=dev-python/hypothesis-3.7.1[${PYTHON_USEDEP}]
+	)
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+python_test() {
+	PYTHONIOENCODING='utf8' \
+	esetup.py test
+}
+
+src_prepare() {
+	default
+	# Fix file collision with app-text/cmark, see bug #627034
+	sed -i -e "s:'cmark\( = commonmark.cmark\:main'\):'cmark.py\1:" \
+		setup.py || die
+}
+
+pkg_postinst() {
+	ewarn "/usr/bin/cmark has been renamed to /usr/bin/cmark.py due file"
+	ewarn "collision with app-text/cmark (see bug #627034)"
+}

dev-python/commonmark/metadata.xml

@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <longdescription lang="en">
+    Pure Python port of jgm’s commonmark.js, a Markdown parser and
+    renderer for the CommonMark specification, using only native
+    modules. Once both this project and the CommonMark specification
+    are stable we will release the first 1.0 version and attempt to
+    keep up to date with changes in commonmark.js.
+  </longdescription>
+  <upstream>
+    <remote-id type="pypi">CommonMark</remote-id>
+    <remote-id type="github">rtfd/CommonMark.py</remote-id>
+  </upstream>
+</pkgmetadata>

dev-python/recommonmark/Manifest

@@ -0,0 +1 @@
+DIST recommonmark-0.6.0.tar.gz 24537 BLAKE2B 47f667ca0799394dc88964709efc59d1e2a68973b1c00fb41abfb514166e939b8dd0b6a0827285cfa1bb60669e08868b7a0993b6a32880fc0dd22cfefa6cf273 SHA512 44005b3fd0052cd8d4fce8a64f9d66a1ac75dc3041a28c115e922254956b2143296cbfbc0a2396b9f95691145645c4242e3be68e695b2c62ae37964014511679

dev-python/recommonmark/metadata.xml

@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <longdescription lang="en">
+    This allows you to write CommonMark inside of Docutils and Sphinx
+    projects.
+  </longdescription>
+  <upstream>
+    <remote-id type="pypi">recommonmark</remote-id>
+    <remote-id type="github">rtfd/recommonmark</remote-id>
+  </upstream>
+</pkgmetadata>

dev-python/recommonmark/recommonmark-0.6.0.ebuild

@@ -0,0 +1,30 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python docutils-compatibility bridge to CommonMark"
+HOMEPAGE="https://recommonmark.readthedocs.io/"
+SRC_URI="https://github.com/rtfd/recommonmark/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/commonmark-0.8[${PYTHON_USEDEP}]
+	>=dev-python/docutils-0.14[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/sphinx-2.0[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_test() {
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}

dev-python/sphinxcontrib-websupport/Manifest

@@ -0,0 +1 @@
+DIST sphinxcontrib-websupport-1.2.0.tar.gz 601365 BLAKE2B eadac8c8895cedd8c38d2fe489b5804a1d2451578cdb8fa0471ae2cf888eb9b36ce0f3f0cfab544b93057f19f088ac0ddea215827b6df7fd9e65b3c3147586fe SHA512 d68cc6415aba88f4c7cd44f04fd45988eefb2a6321311e10b428d487ba84a50c68d6190ad6c560272dc99d386358b756c51f1d87615db068042c6e32eb701b67

dev-python/sphinxcontrib-websupport/metadata.xml

@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <longdescription lang="en">
+    sphinxcontrib-webuspport provides a Python API to easily integrate
+    Sphinx documentation into your Web application.
+  </longdescription>
+  <upstream>
+    <remote-id type="pypi">sphinxcontrib-websupport</remote-id>
+    <remote-id type="github">sphinx-doc/sphinxcontrib-websupport</remote-id>
+  </upstream>
+</pkgmetadata>

dev-python/sphinxcontrib-websupport/sphinxcontrib-websupport-1.2.0.ebuild

@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{6,7,8} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Sphinx websupport extension"
+HOMEPAGE="http://www.sphinx-doc.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/sqlalchemy-0.9[${PYTHON_USEDEP}]
+	>=dev-python/whoosh-2.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.5[${PYTHON_USEDEP}]
+	dev-python/namespace-sphinxcontrib[${PYTHON_USEDEP}]"
+# avoid circular dependency with sphinx
+PDEPEND="
+	>=dev-python/sphinx-2.0[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		${PDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+	)"
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${ED}" -name '*.pth' -delete || die
+}
+
+src_test() {
+	cd tests || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}