From 4f72d2d8638f04f63736babe8fdd160e90fc6d70 Mon Sep 17 00:00:00 2001
From: Alarig Le Lay <alarig@swordarmor.fr>
Date: Tue, 21 Mar 2023 20:18:37 +0100
Subject: [PATCH] dev-python/lazr-delegates: new package, add 2.1.0

---
 dev-python/lazr-delegates/Manifest            |  1 +
 .../lazr-delegates-2.1.0.ebuild               | 38 +++++++++++++++++++
 dev-python/lazr-delegates/metadata.xml        | 15 ++++++++
 3 files changed, 54 insertions(+)
 create mode 100644 dev-python/lazr-delegates/Manifest
 create mode 100644 dev-python/lazr-delegates/lazr-delegates-2.1.0.ebuild
 create mode 100644 dev-python/lazr-delegates/metadata.xml

diff --git a/dev-python/lazr-delegates/Manifest b/dev-python/lazr-delegates/Manifest
new file mode 100644
index 0000000..5f5296e
--- /dev/null
+++ b/dev-python/lazr-delegates/Manifest
@@ -0,0 +1 @@
+DIST lazr-delegates-2.1.0.tar.gz 15877 BLAKE2B b8c9a1f0b473162560a21fc4ea7553786cb38f94ed7da63ccd740f5cd49b566ad5a0ba86270d062aed08dfe67dfc33708252a7761783bdeadb99a6ca1452a0c0 SHA512 e8e081d71afed32aa8b8e898268d1e4a33be6bbdcad7778dfb000b9ad600ae9922032b6d13d066c55106ea403a5a25340fb9f8e1fe3ee246732247cbb3fd108b
diff --git a/dev-python/lazr-delegates/lazr-delegates-2.1.0.ebuild b/dev-python/lazr-delegates/lazr-delegates-2.1.0.ebuild
new file mode 100644
index 0000000..a1023a4
--- /dev/null
+++ b/dev-python/lazr-delegates/lazr-delegates-2.1.0.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+
+DESCRIPTION="Easily write objects that delegate behavior"
+HOMEPAGE="https://code.launchpad.net/lazr.delegates"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/zope-interface[${PYTHON_USEDEP}]
+	!dev-python/namespace-lazr
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# strip unused rdeps
+	sed -i -e "/'setuptools'/d" -e "/'nose'/d" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
diff --git a/dev-python/lazr-delegates/metadata.xml b/dev-python/lazr-delegates/metadata.xml
new file mode 100644
index 0000000..d111162
--- /dev/null
+++ b/dev-python/lazr-delegates/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<maintainer type="person">
+		<email>prometheanfire@gentoo.org</email>
+		<name>Matthew Thode</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">lazr.delegates</remote-id>
+	</upstream>
+</pkgmetadata>