net-misc/FORT-validator: Adding patch for upstream issue #83

https://github.com/NICMx/FORT-validator/issues/83

net-misc/FORT-validator/FORT-validator-1.5.3.ebuild

@@ -32,7 +32,7 @@ BDEPEND="
 	sys-devel/automake
 "
 
-S="${WORKDIR}/fort-${PV}"
+S="${WORKDIR}/${MY_PN}-${PV}"
 
 src_prepare() {
 	default

net-misc/FORT-validator/FORT-validator-1.5.3_p20220607.ebuild

@@ -0,0 +1,74 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools fcaps systemd
+
+MY_PN="fort"
+MY_PV="issue83"
+
+DESCRIPTION="FORT validator is an open source RPKI validator"
+HOMEPAGE="https://fortproject.net/validator?2"
+SRC_URI="https://github.com/NICMx/${PN}/archive/refs/heads/${MY_PV}.zip -> ${MY_PN}-${PV}.zip"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="caps"
+
+DEPEND="
+	acct-group/fort
+	acct-user/fort
+	caps? ( sys-libs/libcap )
+	dev-libs/jansson
+	dev-libs/openssl
+"
+RDEPEND="
+	${DEPEND}
+	net-misc/rsync
+"
+BDEPEND="
+	sys-devel/autoconf
+	sys-devel/automake
+"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+src_prepare() {
+	default
+	# Don't strip CFLAGS
+	sed -i 's/fort_CFLAGS  =/fort_CFLAGS  = ${CFLAGS} /' src/Makefile.am || die
+	# Don't test network
+	sed -i '/http/d' test/Makefile.am || die
+	eautoreconf
+}
+
+src_install() {
+	newinitd "${FILESDIR}/${MY_PN}-1.5-initd" ${MY_PN}
+	newconfd "${FILESDIR}/${MY_PN}-1.5-confd" ${MY_PN}
+
+	emake DESTDIR="${ED}" install
+	insinto /usr/share/${MY_PN}/
+	insopts -m0644 -o "${MY_PN}"
+	diropts -m0755 -o "${MY_PN}"
+	doins -r examples/tal/
+
+	dodoc -r examples/
+
+	insinto /etc/fort
+	newins "${FILESDIR}/fort-config.json" config.json
+
+	systemd_dounit "${FILESDIR}/${MY_PN}-1.5.service"
+}
+
+pkg_postinst() {
+	fcaps cap_net_bind_service usr/bin/fort
+
+	einfo ""
+	einfo "You have to init the TALs before the first run. To do so, run "
+	einfo ""
+	einfo "  su -s /bin/sh -c '${EROOT}/usr/bin/${MY_PN} --init-tals --tal /usr/share/${MY_PN}/tal/' fort"
+	einfo ""
+	einfo "as root."
+}

net-misc/FORT-validator/Manifest

@@ -2,3 +2,4 @@ DIST FORT-validator-1.4.2.tar.gz 471694 BLAKE2B 9c5f3a2a6b79dbd62248e125d665d315
 DIST FORT-validator-1.5.0.tar.gz 482884 BLAKE2B 704f9d9f9c9cea54f8831f669eac62d5298da8ccacfdae5a4ecc30ee126be610679ff25a929d5ead64cb02fd63bdeaebc7027312d7fcb6d49bd0d563bb256fa2 SHA512 3da44896c69685c0a49e418b10e70ad34a5c621a32982203eb3def5462af014d1f807e29e3e9a7555b381ad976e8e19c2cc0973149c9c6253ee845a14fb86023
 DIST fort-1.5.2.tar.gz 562414 BLAKE2B cbe5a5a47ec7a47176ab1cdd9b3ed26e5a73dd238a364d0ec54a5955316e4813a715180652ad2092ed9cf5c843dc7677d33ed831adb5bcabc156995fbf4c208b SHA512 77c9484314067f5612a5a076ae7e16423f41b79220fc911599f867426dedf7b2276b8f8109ad0b17a714c463f3080b734d1562f6b7ed2265583b1ab6c7f32436
 DIST fort-1.5.3.tar.gz 564257 BLAKE2B f0a6c9899c968f6697c79c0f541275874bc7aa23d6e42113d4be23b6338eb3007557a0260e601575719b90b8e87c4483bb13a40a6ac0724e17cf8157ce40d6ba SHA512 1b97bec1b031cd717d4012b0faec36785ba5c8e06ca46b4a017a08c3f2a038d2224c740a6b84f1c853c996c203af9ac975506d5c0e379a7cab82554318136a99
+DIST fort-1.5.3_p20220607.zip 719847 BLAKE2B 10ed3913e6482e15da64f48ce42a0eb9d14b5e39875f8b2ac1dc71da9cccfaa952a3bbb71030bc6c025aa9966087db20e0a574af6da8424b0b24e8d51e98fb23 SHA512 2dfa61a99edffb678ba338165610445921380bf98c32958b4c425dfa055a212ec4edcbf68758f43fdb4f36769a79fceca46e82abdc471e4bea22caf28c879eb3