gemini-client/lagrange: bump to 1.6.1

This commit is contained in:
Anna “CyberTailor” 2021-07-31 22:55:31 +05:00
parent 83cbd92188
commit 3bd137ec64
No known key found for this signature in database
GPG Key ID: E7B76EDC50864BB1
3 changed files with 59 additions and 43 deletions

View File

@ -1,2 +1,2 @@
DIST lagrange-1.5.2.tar.gz 20409523 BLAKE2B 3f8888d7012f7886a61c938c5527639495d0dc424185133b663aec4e90e8de604863bac481a87606cfc5af80a3974503124a8ac7e5924a034053a1cbca705abd SHA512 971d54d072799cc03bc2521571c74e3da996f390198c3a7e04ff8480040aa1ae96d1407dec68ecb02225ece14c0032304ad1c605b6619b4538d9078c8180f9d6
DIST lagrange-1.6.0.tar.gz 22693081 BLAKE2B 447e2d45736b476ea060804ca9b4f382e8e396e4dab6a826756b44742403b35619440e51f59f27ea9e4456677383b069554f7eb034f8b23177dbb0c9a060dfba SHA512 db0e958b959b4dbcb1d34e4fb7c7683750aa8216dcfa7868aa32397b4740552f96d21f6409320ff2a4353fb695e7aa91efafe12ec5db3be00872cd387641efec
DIST lagrange-1.6.1.tar.gz 22698567 BLAKE2B 186b92b92e9e3d97f06a47cae09be0bab3ef583fd60d13672f9ab1c712ba9dbccf609d0585d7966def03d485ac8cfba300cce0a41f9b550b4af89620e5fb7c01 SHA512 36f2d5829f190e195f6ce9611a669874de82b908746a8c71a3e51a51effc1b303a11e0cc838de56ca835e83c7dfd9163b6e1400758365b486961f3d0a977d231

View File

@ -1,42 +0,0 @@
# Copyright 2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit cmake xdg
DESCRIPTION="Desktop GUI client for browsing Geminispace"
HOMEPAGE="https://gmi.skyjake.fi/lagrange/
https://git.skyjake.fi/gemini/lagrange"
SRC_URI="https://git.skyjake.fi/gemini/${PN}/releases/download/v${PV}/${P}.tar.gz"
LICENSE="|| ( MIT Unlicense ) Apache-2.0 BSD-2 OFL-1.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cpu_flags_x86_sse4_1 +mp3"
DEPEND="
dev-libs/libpcre
dev-libs/libunistring
dev-libs/openssl
media-libs/libsdl2
sys-libs/zlib
mp3? ( media-sound/mpg123 )
"
RDEPEND="${DEPEND}"
src_prepare() {
cmake_src_prepare
}
src_configure() {
local mycmakeargs=(
-DENABLE_MPG123=$(usex mp3)
# lib/the_Foundation
-DTFDN_ENABLE_WARN_ERROR=OFF
-DTFDN_ENABLE_SSE41=$(usex cpu_flags_x86_sse4_1)
)
cmake_src_configure
}

View File

@ -0,0 +1,58 @@
# Copyright 2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit xdg cmake
DESCRIPTION="Desktop GUI client for browsing Geminispace"
HOMEPAGE="https://gmi.skyjake.fi/lagrange/
https://git.skyjake.fi/gemini/lagrange"
SRC_URI="https://git.skyjake.fi/gemini/${PN}/releases/download/v${PV}/${P}.tar.gz"
LICENSE="|| ( MIT Unlicense ) Apache-2.0 BSD-2 OFL-1.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cpu_flags_x86_sse4_1 +fribidi +harfbuzz +mp3"
DEPEND="
dev-libs/libpcre:3
dev-libs/libunistring
dev-libs/openssl
media-libs/libsdl2[sound(+),video(+)]
sys-libs/zlib
fribidi? ( dev-libs/fribidi )
harfbuzz? ( media-libs/harfbuzz[truetype(+)] )
mp3? ( media-sound/mpg123 )
"
RDEPEND="${DEPEND}"
src_configure() {
# do not add use flags that don't pull dependencies
# and only choose which files to compile (e.g. "ipc")
local mycmakeargs=(
-DENABLE_FRIBIDI=$(usex fribidi)
-DENABLE_HARFBUZZ=$(usex harfbuzz)
-DENABLE_MPG123=$(usex mp3)
# never build bundled libs
-DENABLE_FRIBIDI_BUILD=OFF
-DENABLE_HARFBUZZ_MINIMAL=OFF
# lib/the_Foundation
-DTFDN_ENABLE_WARN_ERROR=OFF
-DTFDN_ENABLE_SSE41=$(usex cpu_flags_x86_sse4_1)
)
cmake_src_configure
}
pkg_postinst() {
if [[ -n ${REPLACING_VERSIONS} ]] && ver_test ${REPLACING_VERSIONS} -lt 1.6.0 ; then
ewarn "Lagrange 1.6 introduces some breaking changes:"
ewarn
ewarn "- A new TOFU trust store will be created. The old one is kept around but ignored."
ewarn "- App state serialization format has been updated. Downgrading to a previous release"
ewarn " will cause app state to be reset (e.g., tabs closed, navigation history cleared)."
fi
}