From 2f091ad81a2271e2f4d62e3203f764c83c57a963 Mon Sep 17 00:00:00 2001
From: Alarig Le Lay <alarig@swordarmor.fr>
Date: Tue, 20 Aug 2024 19:00:46 +0200
Subject: [PATCH] dev-python/falcon: add 3.1.3

Signed-off-by: Alarig Le Lay <alarig@swordarmor.fr>
---
 dev-python/falcon/Manifest            |  1 +
 dev-python/falcon/falcon-3.1.3.ebuild | 61 +++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)
 create mode 100644 dev-python/falcon/falcon-3.1.3.ebuild

diff --git a/dev-python/falcon/Manifest b/dev-python/falcon/Manifest
index 4889cdd..ad360ef 100644
--- a/dev-python/falcon/Manifest
+++ b/dev-python/falcon/Manifest
@@ -1 +1,2 @@
 DIST falcon-3.1.1.tar.gz 1320543 BLAKE2B 7c9d1bab73df864632f6d649a4a9894b35837bcca91eb05ce67447b4139274cd326e31f88ed3a0015a3dd82509b5d8d7ab1f439d0fdd190957e06b49f51daa9b SHA512 d6d0ff20a64400a28e45bf30de38c1d989f78f0aef97467a1e464aa3bffca8027728948fae604f2fecd00cc79488301b2d842c0c1436ee15f50c666e03ff9ecd
+DIST falcon-3.1.3.tar.gz 1218058 BLAKE2B 1013ec1faac8029f2bfd1182643f0a528ad363eccde26d97abeb907054377a3f08054a812db7349bbf6364304c81a3922de7241bfa5f85c9d3dc6ec7bbfb17ca SHA512 66c5f563b373eb2bc2576d64d2225fa98f4d9d80dc1c93f6831f17287738797ac1f08a1ba71f4a70e6bafad7a51f70fa6fbbee99ef521419ceedcf2d892108ee
diff --git a/dev-python/falcon/falcon-3.1.3.ebuild b/dev-python/falcon/falcon-3.1.3.ebuild
new file mode 100644
index 0000000..6c62811
--- /dev/null
+++ b/dev-python/falcon/falcon-3.1.3.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="A supersonic micro-framework for building cloud APIs"
+HOMEPAGE="
+	https://falconframework.org/
+	https://pypi.org/project/falcon/
+	https://github.com/falconry/falcon/
+"
+SRC_URI="
+	https://github.com/falconry/${PN}/archive/${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="Apache-2.0 MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/aiofiles[${PYTHON_USEDEP}]
+		dev-python/cbor2[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/uvicorn[${PYTHON_USEDEP}]
+		dev-python/websockets[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# uwsgi seems to be broken/incompatible
+		'tests/test_wsgi_servers.py::TestWSGIServer::test_get[uwsgi]'
+		'tests/test_wsgi_servers.py::TestWSGIServer::test_get_deprecated[uwsgi]'
+		'tests/test_wsgi_servers.py::TestWSGIServer::test_post_multipart_form[uwsgi]'
+		'tests/test_wsgi_servers.py::TestWSGIServer::test_static_file[uwsgi]'
+		'tests/test_wsgi_servers.py::TestWSGIServer::test_static_file_byte_range[uwsgi-'
+	)
+
+	local EPYTEST_IGNORE=(
+		# mujson is unpackaged, test-only dep
+		tests/test_media_handlers.py
+	)
+
+	rm -rf falcon || die
+	# needed because servers are spawned via /usr/bin/python*
+	local -x PYTHONPATH=${BUILD_DIR}/install$(python_get_sitedir):${PYTHONPATH}
+	epytest tests
+}