diff --git a/net-misc/FORT-validator/FORT-validator-1.2.1.ebuild b/net-misc/FORT-validator/FORT-validator-1.2.1.ebuild
new file mode 100644
index 0000000..ce424e3
--- /dev/null
+++ b/net-misc/FORT-validator/FORT-validator-1.2.1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools fcaps systemd
+
+DESCRIPTION="FORT validator is an open source RPKI validator"
+HOMEPAGE="https://fortproject.net/validator?2"
+SRC_URI="https://github.com/NICMx/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+MY_PN="fort"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="caps libressl"
+
+DEPEND="
+	acct-group/fort
+	acct-user/fort
+	caps? ( sys-libs/libcap )
+	dev-libs/jansson
+	libressl?	( dev-libs/libressl:0= )
+	!libressl?	( dev-libs/openssl:0= )
+"
+RDEPEND="
+	${DEPEND}
+	net-misc/rsync
+"
+BDEPEND="
+	sys-devel/autoconf
+	sys-devel/automake
+"
+
+PATCHES="${FILESDIR}/${PN}-skip-online-test.patch"
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_install() {
+	newinitd "${FILESDIR}/${MY_PN}-initd" ${MY_PN}
+	newconfd "${FILESDIR}/${MY_PN}-confd" ${MY_PN}
+
+	emake DESTDIR="${D}" install
+	insinto /usr/share/${MY_PN}/
+	insopts -m0644 -o "${MY_PN}"
+	diropts -m0755 -o "${MY_PN}"
+	doins -r examples/tal/
+
+	dodoc -r examples/
+
+	insinto /etc/fort
+	newins "${FILESDIR}/fort-config.json" config.json
+
+	exeinto "/usr/libexec/${MY_PN}"
+	doexe fort_setup.sh
+
+	systemd_dounit "${FILESDIR}/${MY_PN}.service"
+}
+
+pkg_postinst() {
+	fcaps cap_net_bind_service usr/bin/fort
+
+	einfo ""
+	einfo "ARIN TAL is disabled by default because the ARIN Relying Party"
+	einfo "Agreement must be accepted beforehead. Start fort, run"
+	einfo ""
+	einfo "  su -s /bin/sh -c '${EROOT}/usr/libexec/${MY_PN}/fort_setup.sh /usr/share/${MY_PN}/tal/' fort"
+	einfo ""
+	einfo "as root and restart fort to enable it."
+	einfo "The configuration file generation will provide a config file, but a"
+	einfo "simpler one is shiped with the ebuid. Use the one you prefer."
+}
diff --git a/net-misc/FORT-validator/Manifest b/net-misc/FORT-validator/Manifest
index abe9cf9..abb8724 100644
--- a/net-misc/FORT-validator/Manifest
+++ b/net-misc/FORT-validator/Manifest
@@ -1 +1,2 @@
 DIST FORT-validator-1.2.0.tar.gz 427483 BLAKE2B 05fbec44fb17fa188b6196a2b166f2e112224dcf4071cc875ed1f3a147b28acff94c89b0c0a658aaee197e1820d9f53803e73add81e355f7df07713fcdb0df00 SHA512 e89b1aa7c0cd4036d04a017898e1a6017450f5dab96e57c35b0aa532b212b23f7fab17ca117a9461c9bdacca511ea70341e692a4d5e8f277ae8e277c1d48706e
+DIST FORT-validator-1.2.1.tar.gz 431832 BLAKE2B 25459e591a531dcf3326baec06c9e462611f1fd727bd79623d0f5eae0f02b2398e698ea6f0cf7608061f5e125afb056c7dff9b1dcc6fbe01332e573e8c4b1f15 SHA512 87d256a02ca6d3c00bb2245476c126b076f6c57e9eeaefb2dcb0dfed5763b5769731de08e4168c9ce701a2820eeda69c3bf054c8445b910948504fdb7b0b6b50