dev-python/django-allauth: new package, add 0.50.0, 0.53.1

dev-python/django-allauth/Manifest

@@ -0,0 +1,2 @@
+DIST django-allauth-0.50.0.tar.gz 703083 BLAKE2B cb43eb09c5385020a581ecdc97acb74329d9c188f4365d91a46b8d2fe742d1d497bdd08d39cff36c93958e885fa1098a2b15218b296f1d9bf9211320aed247b6 SHA512 bf769e639ad37cfa150ed115b88d8802ae2f407461738a0dd2f39b055a4afc1468fe30d47a86e8f22697d2e67d4277078218c76f6c394a5cc685b7b21fa0a53a
+DIST django-allauth-0.53.1.tar.gz 736728 BLAKE2B 21b8d40a7386a5f0fbdb72efb82bb7588fe2f2d20263067f84d8438239243ea92b21f3b1a82d95c48126f99740010906b3264666c9a09221619997bbf2962722 SHA512 6f0d7067d5522ccd19abf614f4af80b7fc59e42dbb0859c79c8f47aed821ccab2b3ef8092af58c4e647f41d114b084b8cf1729d6fbd4a2c9bfbb691ff41903f0

dev-python/django-allauth/django-allauth-0.50.0.ebuild

@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Django 3rd party (social) account authentication"
+HOMEPAGE="
+	https://www.intenct.nl/projects/django-allauth/
+	https://github.com/pennersr/django-allauth/
+	https://pypi.org/project/django-allauth/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/django[${PYTHON_USEDEP}]
+	dev-python/pyjwt[${PYTHON_USEDEP}]
+	dev-python/python3-openid[${PYTHON_USEDEP}]
+	dev-python/requests-oauthlib[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+"
+# cryptography via pyjwt[crypto]
+RDEPEND+="
+	dev-python/cryptography[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? ( ${RDEPEND} )
+"
+
+DOCS=( README.rst AUTHORS ChangeLog.rst )
+
+src_test() {
+	# cern provider tests require Internet
+	rm allauth/socialaccount/providers/cern/tests.py || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	local -x DJANGO_SETTINGS_MODULE=test_settings
+	local -x PYTHONPATH=.
+	django-admin test -v 2 || die "Tests failed with ${EPYTHON}"
+}

dev-python/django-allauth/django-allauth-0.53.1.ebuild

@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Django 3rd party (social) account authentication"
+HOMEPAGE="
+	https://www.intenct.nl/projects/django-allauth/
+	https://github.com/pennersr/django-allauth/
+	https://pypi.org/project/django-allauth/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/django[${PYTHON_USEDEP}]
+	dev-python/pyjwt[${PYTHON_USEDEP}]
+	dev-python/python3-openid[${PYTHON_USEDEP}]
+	dev-python/requests-oauthlib[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? ( ${RDEPEND} )
+"
+
+DOCS=( README.rst AUTHORS ChangeLog.rst )
+
+src_test() {
+	# cern provider tests require Internet
+	rm allauth/socialaccount/providers/cern/tests.py || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	local -x DJANGO_SETTINGS_MODULE=test_settings
+	local -x PYTHONPATH=.
+	django-admin test -v 2 || die "Tests failed with ${EPYTHON}"
+}

dev-python/django-allauth/metadata.xml

@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">django-allauth</remote-id>
+		<remote-id type="github">pennersr/django-allauth</remote-id>
+	</upstream>
+</pkgmetadata>