From 0c8d76206bde4511c0a229a2a77cb5dcaf0f74d8 Mon Sep 17 00:00:00 2001
From: Alarig Le Lay <alarig@swordarmor.fr>
Date: Tue, 31 Jan 2023 00:48:22 +0100
Subject: [PATCH] dev-python/django-auth-ldap: new package, add 4.1.0

---
 dev-python/django-auth-ldap/Manifest          |  1 +
 .../django-auth-ldap-4.1.0.ebuild             | 49 +++++++++++++++++++
 dev-python/django-auth-ldap/metadata.xml      | 12 +++++
 3 files changed, 62 insertions(+)
 create mode 100644 dev-python/django-auth-ldap/Manifest
 create mode 100644 dev-python/django-auth-ldap/django-auth-ldap-4.1.0.ebuild
 create mode 100644 dev-python/django-auth-ldap/metadata.xml

diff --git a/dev-python/django-auth-ldap/Manifest b/dev-python/django-auth-ldap/Manifest
new file mode 100644
index 0000000..51a71f1
--- /dev/null
+++ b/dev-python/django-auth-ldap/Manifest
@@ -0,0 +1 @@
+DIST django-auth-ldap-4.1.0.gh.tar.gz 49533 BLAKE2B f99050c147d179a54fe052e72a9b2ded556819da788f5180225a6d5015d2b7b52dc6f6d65fac4d1b88dc28b3617f9caaac7df3e455d218e8a2c6af1391418b8e SHA512 d55710cf96916602d29b33e111eff7922011231c47f843660cf2adfdc226dd335d4e42e5c2933bd77a9ee5f816d044798e876c8d0de824dcf4a8a78e1bce3446
diff --git a/dev-python/django-auth-ldap/django-auth-ldap-4.1.0.ebuild b/dev-python/django-auth-ldap/django-auth-ldap-4.1.0.ebuild
new file mode 100644
index 0000000..9dc5687
--- /dev/null
+++ b/dev-python/django-auth-ldap/django-auth-ldap-4.1.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Django LDAP authentication backend"
+HOMEPAGE="
+	https://github.com/django-auth-ldap/django-auth-ldap/
+	https://pypi.org/project/django-auth-ldap/
+"
+SRC_URI="
+	https://github.com/django-auth-ldap/django-auth-ldap/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+LICENSE="BSD-2"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/django-2.2[${PYTHON_USEDEP}]
+	>=dev-python/python-ldap-3.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_impl_dep sqlite)
+		net-nds/openldap[-minimal]
+	)
+"
+
+distutils_enable_sphinx docs --no-autodoc
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	# for slapd and slapdtest
+	local -x SBIN=/usr/sbin:/usr/$(get_libdir)/openldap
+	"${EPYTHON}" -m django test -v 2 --settings tests.settings ||
+		die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/django-auth-ldap/metadata.xml b/dev-python/django-auth-ldap/metadata.xml
new file mode 100644
index 0000000..414a8df
--- /dev/null
+++ b/dev-python/django-auth-ldap/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="pypi">django-auth-ldap</remote-id>
+    <remote-id type="github">django-auth-ldap/django-auth-ldap</remote-id>
+  </upstream>
+</pkgmetadata>