Add a more recent youtube-dl release

This commit is contained in:
Alarig Le Lay 2018-11-17 13:08:32 +01:00
parent e98b2d656d
commit 08ec46219f
2 changed files with 119 additions and 0 deletions

View File

@ -0,0 +1,2 @@
DIST youtube-dl-2018.11.07.tar.gz 3053158 BLAKE2B e6220003a570158d0da2b054489297ac2c65b7e657d9e713a1229d2b22ed0a1d2e29d171809f5cdb76a5e22e11add15b25449729e1f58316450cf7054c0ded8b SHA512 9bb552e1343d151c98aa20a91728d59cfea1ec24d838533af57a3d25c5ab4be7e1de2aac2e426632835a20ed0ef3516ce3c8cccdc9b0d2505bd1516d5b9e910d
EBUILD youtube-dl-2018.11.07.ebuild 3439 BLAKE2B 2e9fcd2e40f815a9d75bb7adff01f12afa5345c027f5dc55b9e20b30a3055bef402d66361048a9cc6cb71e1e6b3982e3b059bee837fb8d36c886be616d078490 SHA512 b46ab94dffbea58076d3b83de105a1c51ed1ae2213ff9b26b074cdcc41ec8ed97223baf92aec78ca2c56d0614826893a01ee0ca8e2e5667561dc43fec12ebbca

View File

@ -0,0 +1,117 @@
# Copyright 1999-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=(python{2_7,3_4,3_5,3_6})
inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
DESCRIPTION="Download videos from YouTube.com (and more sites...)"
HOMEPAGE="https://rg3.github.com/youtube-dl/"
SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
LICENSE="public-domain"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
IUSE="+offensive test"
RDEPEND="
dev-python/setuptools[${PYTHON_USEDEP}]
"
DEPEND="
${RDEPEND}
test? ( dev-python/nose[coverage(+)] )
"
S="${WORKDIR}/${PN}"
python_prepare_all() {
if ! use offensive; then
sed -i -e "/..version../s|'$|+gentoo.no.offensive.sites'|g" \
youtube_dl/version.py || die
# these have single line import statements
local xxx=(
alphaporno anysex behindkink camwithher chaturbate eporner
eroprofile extremetube foxgay goshgay hellporno hentaistigma
hornbunny keezmovies lovehomeporn mofosex myvidster porn91 porncom
pornflip pornhd pornotube pornovoisines pornoxo ruleporn sexu
slutload spankbang spankwire sunporno thisav vporn watchindianporn
xbef xnxx xtube xvideos xxxymovies youjizz youporn
)
# these have multi-line import statements
local mxxx=(
drtuber fourtube motherless pornhub redtube tnaflix tube8 xhamster
)
# do single line imports
sed -i \
-e $( printf '/%s/d;' ${xxx[@]} ) \
youtube_dl/extractor/extractors.py \
|| die
# do multiple line imports
sed -i \
-e $( printf '/%s/,/)/d;' ${mxxx[@]} ) \
youtube_dl/extractor/extractors.py \
|| die
sed -i \
-e $( printf '/%s/d;' ${mxxx[@]} ) \
youtube_dl/extractor/generic.py \
|| die
rm \
$( printf 'youtube_dl/extractor/%s.py ' ${xxx[@]} ) \
$( printf 'youtube_dl/extractor/%s.py ' ${mxxx[@]} ) \
test/test_age_restriction.py \
|| die
fi
eapply_user
distutils-r1_python_prepare_all
}
src_compile() {
distutils-r1_src_compile
}
python_test() {
emake test
}
python_install_all() {
dodoc README.txt
doman ${PN}.1
newbashcomp ${PN}.bash-completion ${PN}
insinto /usr/share/zsh/site-functions
newins youtube-dl.zsh _youtube-dl
insinto /usr/share/fish/vendor_completions.d
doins youtube-dl.fish
distutils-r1_python_install_all
rm -r "${ED}"/usr/etc || die
rm -r "${ED}"/usr/share/doc/youtube_dl || die
}
pkg_postinst() {
elog "youtube-dl(1) / https://bugs.gentoo.org/355661 /"
elog "https://github.com/rg3/youtube-dl/blob/master/README.md#faq :"
elog
elog "${PN} works fine on its own on most sites. However, if you want"
elog "to convert video/audio, you'll need avconf (media-video/libav) or"
elog "ffmpeg (media-video/ffmpeg). On some sites - most notably YouTube -"
elog "videos can be retrieved in a higher quality format without sound."
elog "${PN} will detect whether avconv/ffmpeg is present and"
elog "automatically pick the best option."
elog
elog "Videos or video formats streamed via RTMP protocol can only be"
elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
elog "Downloading MMS and RTSP videos requires either mplayer"
elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
elog
elog "If you want ${PN} to embed thumbnails from the metadata into the"
elog "resulting MP4 files, consider installing media-video/atomicparsley"
}