dev-libs/liblinphone: py3.11

dev-libs/liblinphone/Manifest

@@ -1 +1,2 @@
-DIST liblinphone-5.1.3.tar.gz 22720534 BLAKE2B a365aa97efd2fc246dc29c412787ecd728131a31fea990a448131332d9fcf9a77c6ad7d6f421609d8441049f3a16600f8f8f0920a60cb6ccda0aaa14620a0548 SHA512 e0df5d9c47ccc2cf1cf2b8fff171f6305240f6f64f5dce42d62792ef7238b1a2c5178a2f4257f4501c417941cc67a007658e473864e2b5ea4ebc2a8e28ff174e
+DIST liblinphone-5.1.3.tar.bz2 20137691 BLAKE2B 8c50d1f4a3ae0cc8e0dbb20374ea508e59a532daf49a62399c70798e8f631fdf7fe82239928240f8b755893e8ba43a8d81bd62b2dfd39553a4747a2589f0ff73 SHA512 5fb29cb56c3d33f030df5f244a7048bb901ced5f7011b6019434244ba7f276df81bd62ad62b08fda1ebb8e6e103c8a25630af9733cede89cca6023539b53d948
+DIST liblinphone-5.2.53.tar.bz2 20410946 BLAKE2B 0a794040316b00d23127f5c4d30ed966e23ec7968a5c36247c0d8482e8d413ebaafc182ef79891d5345e3053abbc78789a866a2cc8b87f5f02c0420fa2402073 SHA512 9db5360ad196470fd76f2e5c0f47db22faf41b5e5c544f9fc886c003de4ebd832efe319d9bdedf85c5a595fc96d41a047fbe52891a5f6398a6019b5c07424d1d

dev-libs/liblinphone/liblinphone-5.1.3.ebuild

@@ -9,7 +9,7 @@ inherit cmake python-r1
 
 DESCRIPTION="SIP library supporting voice/video calls and text messaging"
 HOMEPAGE="https://gitlab.linphone.org/BC/public/liblinphone"
-SRC_URI="https://gitlab.linphone.org/BC/public/${PN}/-/archive/${PV}/${P}.tar.gz"
+SRC_URI="https://gitlab.linphone.org/BC/public/${PN}/-/archive/${PV}/${P}.tar.bz2"
 
 LICENSE="GPL-3"
 KEYWORDS="~amd64 ~x86"

dev-libs/liblinphone/liblinphone-5.2.53.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit cmake python-r1
+
+DESCRIPTION="SIP library supporting voice/video calls and text messaging"
+HOMEPAGE="https://gitlab.linphone.org/BC/public/liblinphone"
+SRC_URI="https://gitlab.linphone.org/BC/public/${PN}/-/archive/${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="debug doc ldap libnotify static-libs test tools"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-cpp/belr
+	dev-cpp/xsd
+	dev-db/sqlite:3
+	dev-db/soci
+	dev-libs/belcard
+	dev-libs/belle-sip
+	dev-libs/jsoncpp:0=
+	dev-libs/libxml2:2
+	dev-libs/lime
+	dev-libs/xerces-c
+	net-libs/bctoolbox[test?]
+	net-libs/ortp
+	media-libs/mediastreamer2[zrtp,srtp,jpeg]
+	sys-libs/zlib:0
+	virtual/libiconv
+	virtual/libintl
+	virtual/libudev
+	tools? ( ${PYTHON_DEPS}
+		dev-python/pystache[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}] )"
+DEPEND="${RDEPEND}"
+BDEPEND="${PYTHON_DEPS}
+	app-doc/doxygen[dot]
+	dev-python/pystache[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-vcs/git
+	virtual/pkgconfig
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+PATCHES=( "${FILESDIR}"/"${P}"-jsoncpp-cmake.patch )
+
+src_prepare() {
+	# QnD fix: incapability to detect jsoncpp
+	sed -i '/json\/json.h/s|<|<jsoncpp/|' src/FlexiAPIClient.{cc,hh} \
+		tester/{flexiapiclient-tester,remote-provisioning-tester}.cpp \
+		|| die "sed failed for FlexiAPIClient"
+	sed -i 's/jsoncpp_object/jsoncpp/' {src,tester}/CMakeLists.txt \
+		|| die "sed failed for src/CMakeLists.txt and tester/CMakeLists.txt"
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_ASSISTANT=YES
+		-DENABLE_DEBUG_LOGS="$(usex debug)"
+		-DENABLE_DOC="$(usex doc)"
+		-DENABLE_FLEXIAPI=YES
+		-DENABLE_LDAP="$(usex ldap)"
+		-DENABLE_LIME=NO
+		-DENABLE_NOTIFY="$(usex libnotify)"
+		-DENABLE_STATIC="$(usex static-libs)"
+		-DENABLE_TOOLS="$(usex tools)"
+		-DENABLE_UNIT_TESTS="$(usex test)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	"${S}"_build/tester/liblinphone_tester \
+		--resource-dir "${S}"/tester/ \
+		|| die "tests failed"
+
+	cmake_src_test
+}